#! /bin/csh -f
# Last edited on 2001-07-05 22:59:25 by mc726

set usage = "$0 [ --help | -h ] FILE.{java,gif,jpg,XXd,html}..."

umask 022

while ( ( $#argv > 0 ) && ( "$1" =~ -* ) ) 
  if ( ( $#argv > 0 ) && ( "$1" == "--help" ) ) then
    echo "usage: ${usage}"; exit 0
  else
    echo 'invalid option "'"$1"'"';
    echo "usage: ${usage}"; exit 1
  endif
end

if ( $#argv == 0 ) then
  echo 'no files?';
  echo "usage: ${usage}"; exit 1
endif
  
set files = ( $* )

set qdir = "${STOLFIHOME}/PUB/mc726"
set qname = "${qdir}/${USER}"

if ( ! ( -d ${STOLFIHOME}/PUB ) ) mkdir ${STOLFIHOME}/PUB
if ( ! ( -d ${qdir} ) ) mkdir ${qdir}
chmod a+rX ${STOLFIHOME}/PUB ${qdir}
if ( -o ${qname}.chkerr ) chmod u+w ${qname}.chkerr
/bin/rm -f ${qname}.chk ${qname}.chkerr
sync

echo "enqueuing the checkin request..."
chmod a+w ${STOLFIHOME}/PUB ${qdir}
sync
echo `pwd` > ${qname}.tmp
ls -1d ${files} >> ${qname}.tmp
chmod a+rw ${qname}.tmp 
mv ${qname}.tmp ${qname}.chk
sync

echo "waiting for checkin request to be processed..."
while ( -r ${qname}.chk ) 
  printf '.' ; sleep 2; sync
end
echo "done"
sleep 1

chmod og-w ${qdir} ${STOLFIHOME}/PUB 
if ( -r ${qname}.chkerr) then
  cat ${qname}.chkerr | sed -e 's/^/  » /g'
else
  echo "TOOL BUG: no file ${qname}.chkerr"
endif