// Last edited on 2010-05-15 23:39:56 by stolfilocal
// Caption: A wood screw hole in particlebord and wood.

global_settings { assumed_gamma 2.2 }
#declare eps = 0.001;  // Skosh to keep surfaces from touching.

background { color rgb <1.000, 1.000, 1.000>  }

#include "pst_axes.inc"
#include "pst_textures.inc"
#include "pst_screws.inc"
#include "pst_stage.inc"

#declare hole =
  object{ wood_screw_hole(20.0,1.0) }

#declare scene = 
  union{
    difference{ 
      object{ wood_block
        ( 15, 15, 50,
          texture{ tx_wood_grain },
          texture{ tx_wood_grain },
          texture{ tx_wood_cut   }
        )
      }
      object{ hole translate 57*z texture{ tx_wood_cut } }
      plane{ -x, 0 texture{ tx_wood_grain } }
    }
    difference{ 
      object{ wood_block
        ( 30, 30, 7,
          texture{ tx_chipboard_cut  },
          texture{ tx_chipboard_cut  },
          texture{ tx_chipboard_face }
        )
        translate 50*z
      }
      object{ hole translate 57*z texture{ tx_chipboard_cut } }
      plane{ -x, 0 texture{ tx_chipboard_cut } }
    }
  }

#declare scene_min = min_extent(scene);
#declare scene_max = max_extent(scene);
#declare scene_rad = vlength(scene_max - scene_min)/2;
#declare scene_ctr = (scene_min + scene_max)/2;

object{ scene }
object{ axes(0.05,10)}
plane{ z,0 translate -100 texture{ tx_tile_floor } }

#declare viewAzim = 0.0;
#declare viewElev = 30.0;
#declare viewDist = 8*scene_rad;
#declare viewRadius = 1.00*scene_rad;
#declare viewCenter = scene_ctr;

#include "pst_camlight.inc"

camlight(viewCenter, viewAzim, viewElev, viewDist, viewRadius, z, 2, 1.00)