// Last edited on 2011-04-25 09:28:50 by stolfi

#macro boneco_corpo()
  cylinder{ < 0,0,0 >, < 0,0,10 >, 3 }
#end

#macro boneco_coxa()
  // Quadril na origem:
  union{
    sphere{ < 0,0,0>, 0.5 }
    cylinder{ < 0,0,0 >, < 0,0,-5 >, 0.5 }
  }
#end

#macro boneco_peh()
  // Tornozelo na origem:
  union{
    sphere{ < 0,0,0 >, 0.5 }
    cylinder{ < 0,0,0 >, < 3,0,0 >, 0.5 }
    sphere{ < 3,0,0 >, 0.5 }
  }
#end

#macro boneco_canela()
  // Joelho na origem
  union{
    sphere{ < 0,0,0 >, 0.5 }
    cylinder{ < 0,0,0 >, < 0,0,-5 >, 0.5 }
  }
#end

#macro boneco_canela_com_peh(AT)
  union{
    object{ boneco_canela() }
    object{ boneco_peh() rotate AT*y translate < 0,0,-5> }
  }
#end

#macro boneco_perna(AJ,AT)
  // AJ é o angulo do joelho em graus.
  // Quadril na origem
  union{
    object{ boneco_coxa()   }
    object{ boneco_canela_com_peh(AT) rotate AJ*y translate < 0,0,-5 > }
  }
#end

#macro boneco(AE,AD, AJE,AJD, ATE,ATD)
  union{
    object{ boneco_corpo() }
    object{ boneco_perna(AJE,ATE) rotate AE*y translate < 0,+3,0> }
    object{ boneco_perna(AJD,ATD) rotate AD*y translate < 0,-3,0> }
  }
#end