// Last edited on 2010-05-16 02:51:03 by stolfilocal
// TEXTURES ////////////////////////////////////////////////////////////

#declare tx_gauge =
  texture{
    pigment{ color rgb 0.95*<1,1,1> }
    finish{ ambient 0.0 diffuse 1.0 }
  }

#declare tx_gauge_cut =
  texture{
    pigment{ color rgb 0.85*<1,1,1> }
    finish{ ambient 0.0 diffuse 1.0 }
  }

#declare tx_matte_white = 
  texture{
    pigment{ color rgb 0.95*<1,1,1> }
    finish{ ambient 0.0 diffuse 1.0 }
  }

#declare tx_matte_black = 
  texture{
    pigment{ color rgb 0.35*<1,1,1> }
    finish{ ambient 0.1 diffuse 0.9 }
  }

#declare tx_steel =
  texture{
    pigment{ color rgb < 0.80, 0.93, 0.94 > }
    finish{ ambient 0.1 diffuse 0.9 specular 0.05 roughness 0.005 }
  }

#declare tx_aluminum = 
  texture{
    pigment{ color rgb 0.95*<1,1,1> }
    finish{ ambient 0.1 diffuse 0.9 specular 0.1 roughness 0.005 }
  }

#declare tx_aluminum_cut = 
  texture{
    pigment{ color rgb 0.95*<1,1,1> }
    finish{ ambient 0.1 diffuse 0.9 specular 0.3 roughness 0.005 }
  }

#declare tx_rig_base = 
  texture{
    pigment{ color rgb < 0.95, 0.90, 0.80 > }
    finish{ ambient 0.1 diffuse 0.9 specular 0.3 roughness 0.005 }
  } 

#declare tx_camera_body = 
  texture{
    pigment{ color rgb < 0.90, 0.20, 1.00 > }
    finish{ ambient 0.1 diffuse 0.4 specular 0.1 roughness 0.005 reflection 0.5*< 0.90, 0.20, 1.00 > }
    normal{ 
      wrinkles 0.1
      scale 0.1
    }
  } 

#declare tx_camera_lens_barrel = 
  texture{
    pigment{ color rgb 0.10*<1,1,1> }
    finish{ ambient 0.1 diffuse 0.9 specular 0.3 roughness 0.005 }
  } 

#declare tx_handle = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.20 > }
    finish{ ambient 0.1 diffuse 0.9 specular 0.3 roughness 0.005 }
  } 

#declare tx_velvet_black = 
  texture{
    pigment{ color rgb 0.05*<1,1,1> }
    finish{ ambient 0.0 diffuse 1.0 }
  }

#declare tx_velvet_verso = 
  texture{
    pigment{ color rgb < 0.50, 0.45, 0.35 > }
    finish{ ambient 0.1 diffuse 0.9 }
  }

#declare tx_paper = 
  texture{
    pigment{ color rgb 0.98*<1,1,1> }
    finish{ ambient 0.0 diffuse 1.0 }
  }

#declare tx_laser_black = 
  texture{
    pigment{ color rgb 0.05*<1,1,1> }
    finish{ ambient 0.0 diffuse 0.8 specular 0.2 roughness 0.005 }
  }

#declare tx_bolt_smooth = 
  texture{
    pigment{ color rgb < 0.54, 0.52, 0.50 > }
    finish{ ambient 0.1 diffuse 0.9 specular 0.05 roughness 0.005 }
  }

#declare tx_screw_smooth = 
  texture{
    pigment{ color rgb 0.95*<0.98,1.00,0.98> }
    finish{ ambient 0.1 diffuse 0.5 specular 0.2 roughness 0.0005 reflection 0.4*<0.98,1.00,0.98> }
    normal{ wrinkles 0.1 scale 0.25 }
  }

#declare tx_screw_thread = 
  texture{
    pigment{ color rgb 0.95*<0.98,1,0.98> }
    finish{ ambient 0.1 diffuse 0.5 specular 0.2 roughness 0.0005 reflection 0.4*<0.98,1.00,0.98> }
    normal{
      marble 1.5
      rotate 90*y
      scale <1.0, 1.0, 0.5>
    }
  }

#declare tx_tile_floor = 
  texture{
    pigment{ checker color rgb < 0.90,0.80,0.60 >, color rgb < 0.80,0.70,0.50 >}
    finish{ ambient 0.1 diffuse 0.9 specular 0.1 roughness 0.0005 }
    scale <20,20,20>
  }

#declare color_chipboard_dark = < 0.75, 0.65, 0.45 >; 
#declare color_chipboard_lite = < 0.97, 0.87, 0.70 >; 
#declare color_chipboard_mean = (color_chipboard_lite + color_chipboard_dark)/2; 

#declare tx_chipboard_face =
  texture{
    pigment{
      granite 
      turbulence 0.05
      color_map{ 
        [ 0.0, 0.8  
          color rgb color_chipboard_lite
          color rgb color_chipboard_lite
        ]
        [ 0.8, 1.01 
          color rgb color_chipboard_mean
          color rgb color_chipboard_dark
        ]
      }
    }
    normal{
      granite 0.1
      scale <0.5, 0.5, 0.5>
    }
    finish {diffuse 0.95 ambient 0.05}
    scale 2
  }

#declare tx_chipboard_cut =
  texture{
    pigment{
      granite
      turbulence 0.2
      color_map{ 
        [ 0.0, 0.8  
          color rgb color_chipboard_lite
          color rgb color_chipboard_lite
        ]
        [ 0.8, 1.01 
          color rgb color_chipboard_mean
          color rgb color_chipboard_dark
        ]
      }
    }
    normal{
      granite 0.5
      scale <0.5, 0.5, 0.5>
    }
    finish {diffuse 0.95 ambient 0.05}
    scale 2
  }

#declare color_wood_dark = < 0.81, 0.60, 0.35 >; 
#declare color_wood_lite = < 1.00, 0.85, 0.70 >; 
#declare color_wood_mean = (color_wood_lite + color_wood_dark)/2; 

#declare tx_wood_grain =
  texture{
    pigment{
      wood
      turbulence 0.2
      color_map{ 
        [ 0.0, 0.8  
          color rgb color_wood_lite
          color rgb color_wood_lite
        ]
        [ 0.8, 1.01 
          color rgb color_wood_mean
          color rgb color_wood_dark
        ]
      }
      scale <1.0, 1.0, 200>
    }
    normal{
      wrinkles 0.4
      scale <0.5, 0.5, 200>
    }
    finish {diffuse 0.95 ambient 0.05}
    scale 4
  }

#declare tx_wood_cut =
  texture{
    pigment{
      color rgb color_wood_mean
    }
    normal{
      wrinkles 0.25
      scale <0.25, 0.25, 0.25>
    }
    finish {diffuse 0.95 ambient 0.05}
    scale 4
  }

#declare tx_cutaway =
  texture{ 
    pigment{ color rgb < 0.80, 0.10, 0.10 > }
    finish { diffuse 0.9 ambient 0.1 }
  }

#macro pigment_splotches(color_A,color_B,color_C)
  pigment{ waves 
    color_map{
      [ 00.00 color rgb color_C ]
      [ +0.35 color rgb color_C ]
      
      [ +0.35 color rgb color_B ]
      [ +0.45 color rgb color_B ]
      
      [ +0.45 color rgb color_A ]
      [ +0.55 color rgb color_A ]
      
      [ +0.55 color rgb color_B ]
      [ +0.65 color rgb color_B ]
      
      [ +0.65 color rgb color_C ]
      [ +1.00 color rgb color_C ]
    }
    warp{ turbulence 0.05 }
  }
#end

#declare color_bozo_A = < 0.100, 0.680, 0.050 >;
#declare color_bozo_B = < 0.980, 0.780, 0.500 >;
#declare color_bozo_C = < 0.880, 0.100, 0.450 >;

#declare tx_matte_bozo =
  texture{
    pigment_splotches(color_bozo_A,color_bozo_B,color_bozo_C)
    finish{ ambient 0.0 diffuse 1.0 specular 0 } 
    scale 0.1
  }

#declare color_spots_A = < 0.400, 0.280, 0.150 >;
#declare color_spots_B = < 0.980, 0.780, 0.300 >;

#declare tx_matte_spots =
  texture{
    pigment_splotches(color_spots_A,color_spots_B,color_spots_A)
    finish{ ambient 0.0 diffuse 1.0 specular 0 } 
    scale 0.1
  }