//  SIBGRAPI'99 poster: title
//  Last edited on 1999-10-08 18:37:01 by stolfi

//  Requires
//    prose_title_texture
//    prose_subtitle_texture
//    prose_location_texture
//
// The top block has has X to the left, Y up, with Y=0 at the top edge,
//      X=0 at the left edge.
//
//    prose_top        = top part of prose: title, subtitle, location line
//
//    prose_top_height = height of prose_top
//    prose_top_width  = width of prose_top

#declare prose_top_width = 1.10;

// Size and extra spacing of fonts instances
#declare prose_title_size = 0.07 * 0.989;
#declare prose_title_stretch = 1.0;

#declare prose_subtitle_size = 0.02 * 0.947;
#declare prose_subtitle_stretch = 0.302;

#declare prose_location_size = 0.03;
#declare prose_location_stretch = 0.328;

// Positions and sizes of individual components:

#declare prose_title_height = 1.40*prose_title_size;
#declare prose_title_y = 0 - prose_title_height;

#declare prose_subtitle_height = 1.40*prose_subtitle_size;
#declare prose_subtitle_y = prose_title_y - prose_subtitle_height;

#declare prose_location_height = 1.20*prose_location_size;
#declare prose_location_y = prose_subtitle_y - prose_location_height;

#declare prose_top_height = 
  prose_title_height + prose_subtitle_height + prose_location_height;

// Title, with y=0 at top edge, x=0 at left edge
#declare prose_top =
  union{
    // Text at the top
    #declare ty = 0;

    #declare sz = prose_title_size;
    #declare hg = prose_title_height/1.2;

    #declare ty = ty - 1.20*hg;
    text { ttf "tt-fonts/arial.ttf"
      "SIBGRAPI'99"
      0.05, prose_title_stretch*x
      texture{ prose_title_texture }
      scale sz translate < 0, ty, 0 >
    } 
    #declare ty = ty - 0.20*hg;

    #declare sz = prose_subtitle_size;
    #declare hg = prose_subtitle_height/1.2;

    #declare ty = ty - 1.20*hg;
    text { ttf "tt-fonts/arial.ttf"
      "XII BRAZILIAN SYMPOSIUM ON COMPUTER GRAPHICS AND IMAGE PROCESSING"
      0.05, prose_subtitle_stretch*x
      texture{ prose_subtitle_texture }
      scale sz translate < 0, ty, 0 >
    } 
    #declare ty = ty - 0.20*hg;

    #declare sz = prose_location_size;
    #declare hg = prose_location_height/1.2;

    #declare ty = ty - 1.10*hg;
    text { ttf "tt-fonts/arial.ttf"
      "OCTOBER 17-20, 1999 - CAMPINAS, SP - BRAZIL"
      0.05, prose_location_stretch*x
      texture{ prose_location_texture }
      scale sz translate < 0, ty, 0 >
    } 
    #declare ty = ty - 0.10*hg;
  }