#declare mb_brick_texture =
  texture {
    pigment {
      bumps 
      color_map {
        [ 0.0 color rgb < 0.50, 0.53, 0.55 > ]
        [ 1.0 color rgb < 0.45, 0.43, 0.40 > ]
      }
    } 
    finish { diffuse 0.95 ambient 0.05 specular 0.05 roughness 0.01 } 
    normal { 
      brick 
        normal { granite 0.5 scale 0.05 }, 
        normal { granite 0.2 scale 0.2 }
      brick_size < 0.240, 0.240, 0.060 > 
      mortar 0.020
      translate 0.050
    }
  }


#macro mb_window_hole(sx,sz,th)
  union {
    box { 
      < -0.5*sx, -0.55*th, 0 >,
      < +0.5*sx, +0.55*th, sz-0.5*sx >
    }
    cylinder {
      < 0, -0.55*th, sz-0.5*sx >,
      < 0, +0.55*th, sz-0.5*sx >,
      0.49999*sx
    }
  }
#end

#declare mb_room_window_B_hole = 
  mb_window_hole(mb_window_B_width, mb_window_B_height, mb_room_wall_thk)
  
#declare mb_room_window_A_hole = 
  mb_window_hole(mb_window_A_width, mb_window_A_height, mb_room_wall_thk)
  
#declare mb_room_walls_basic = 
  difference { 
    box { 
      -0.5*(mb_room_dims + 0.5*mb_room_wall_thk), 
      +0.5*(mb_room_dims + 0.5*mb_room_wall_thk)
    }
    box { 
      -0.5*(mb_room_dims - 0.5*mb_room_wall_thk), 
      +0.5*(mb_room_dims - 0.5*mb_room_wall_thk)
    }
    translate 0.5 * mb_room_dims.z * z
  }