#! /bin/csh -f
# Last edited on 2004-10-13 23:36:31 by stolfi

# Comparing the whole files:

set dffile = "jek-js.diff"
echo "diff {orig,main}.jek --> ${dffile}"
diff -bB orig.jek main.jek \
  | prettify-diff-output \
  > ${dffile}
printf "  '<' = "; egrep -e '^ *[<]' ${dffile} | wc -l
printf "  '>' = "; egrep -e '^ *[>]' ${dffile} | wc -l

# Comparing OP and English token sequences:

foreach gt ( en/'ti|st|dt|au|pr|tr|nt|nk|nr|xr' op/'op' )
  set lang = "${gt:h}"
  set tags = "${gt:t}"
  set dargs = ( )
  echo "lang = ${lang} tags = ${tags}"
  foreach vers ( orig main )
    set infile = "${vers}.jek"
    set otfile = "${vers}-${lang}.tks"
    echo "${infile} --> ${otfile}"
    cat ${infile} \
      | egrep -e '^[\\]('"${tags}"')' \
      | tee ${vers}-${lang}.tmp \
      | sed \
          -e '/[\\](tt|dt|au)/s/ /_/g' \
      | tr 'A-ZÈ' 'a-zè' \
      | tr ' ' '\012' \
      | egrep -v -e '^[/]$' \
      > ${otfile}
    set dargs = ( ${dargs} ${otfile} )
  end
  set dffile = ${lang}.tdf
  echo "diff ${dargs} --> ${dffile}"
  diff -Bb ${dargs} \
    | prettify-diff-output \
    > ${dffile}
  printf "  '<' = "; egrep -e '^ *[<]' ${dffile} | wc -l
  printf "  '>' = "; egrep -e '^ *[>]' ${dffile} | wc -l
end