#! /bin/csh -f
# Last modified on Mon Jan 19 18:23:32 1987 by stolfi
#================================================
# Usage: bibtex-all [options]
# 
# Lists all bibliography entries in the current directory.
#
# The entries should be files matching [A-Z][A-Z]-[0-9]*.
# The options are those of bibtex.
# The dummy file bibprinted.date is touched, for the benfit of
#   bibtex-new and biblist-new.
#================================================
# Check whether all args begin with "-"
set texopt=""
while ( ( $#argv > 0 ) && ( "$1" =~ -* ) )
  set  texopt= ( $texopt $1 )
  shift
end
if ( $#argv != 0 ) then
  echo "Usage: bibtex-all [options...]"
  exit 1
endif
bibtex $texopt [A-Z][A-Z]-[0-9] [A-Z][A-Z]-[0-9][0-9] 
foreach n (1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16)
  # get a hundred files more
  set nonomatch; set files = (`ls [A-Z][A-Z]-${n}[0-9][0-9]`); unset nonomatch
  if ($#files > 0) then
    bibtex $texopt $files
  endif
end
touch bibprinted.date 
#================================================