#! /bin/csh -f -e

# The goal of this test is to illustrate the effect of varying 
# the weights of the energy functions

if ( $#argv != 1 ) then
  echo "usage: run-test <nice-shape-name>"
  exit 1
endif

set infile = "$1"
set infile = "${infile:r}"

set pg = ~marcone/progs/m3-3.5.3/
set nice = ../nice-shapes

# Copy all data to a sub-directory and runs test there

set d = "${infile}/`date +%y-%m-%d-%H%M%S`"

echo "running test in ${d}"

mkdir -p $d $d/src-save
cp -p ${nice}/${infile}.top ${d}
cp -p ${pg}/libm3marcone/src/{*Energy}.?3 ${d}/src-save
cp -p ${pg}/OptShape/src/OptShape.m3 ${d}/src-save
cp -p run-big-test show-test-plots monotone-energy-plot.nawk ${d}
chmod -R a-w ${d}/*

cd ${d}

#  "Usage: OptShape \\\n");
#  "  -inFile <name>   -outFile <name> \\\n");
#  "  [ -vertexPasses <num> ] \\\n");
#  "  [ -maxEvals <num> ] \\\n");
#  "  [ -showEvery <num> | -showAll ] \\\n");
#  ParseMinimizerParams.Help);
#  " \\\n");
#  ParseEnergyParams.Help);
#  "\n");

set maxev = 5000
set every = 50

foreach comb ( \
  Curv \
  Excen \
  Corner \
)
  set ea = ${comb:r}

  foreach wts ( \
    083.008.008  008.083.008  008.008.083 \
    044.044.011  044.011.044  011.044.044 \
    033.033.033 \
  )
  
    set tmp = ${wts:r}
    set wa = ${tmp:r}
    set wb = ${tmp:e}
    set wc = ${wts:e}
    
    set outfile = "${infile}-${ea}${wa}+Elect${wb}+PArea${wc}"
    
    set wwa = "`echo $wa | sed -e 's/^\(.\)/\1\./'`"
    set wwb = "`echo $wb | sed -e 's/^\(.\)/\1\./'`"
    set wwc = "`echo $wc | sed -e 's/^\(.\)/\1\./'`"
    
    nice OptShape \
      -inFile ${infile} \
      -outFile ${outfile} \
      -maxEvals ${maxev} \
      -showEvery ${every} \
      -minimizer Grad Euler \
      -energy ${wwa} ${ea} \
      -energy ${wwb} Elect fuzz 0.1 \
      -energy ${wwc} PArea area 0.5
      
    gzip ${outfile}.st ${outfile}.plot
  
    # show-top ${outfile}-final

    # show-test-plots ${outfile}.plot 

  end

end