// Last edited on 2004-11-23 19:28:07 by stolfi

#declare cam_ctr = <0,0,4.0>;
#declare cam_dir = <4,3,3>;

camera {
  location  cam_ctr + 5*cam_dir   // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   cam_ctr  // Para onde a câmera está apontando.
} 

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 1.00, 0.30 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare G = seed(4615);

#macro arvore(n,sz)
  #local h = (0.8 + 0.2*rand(G))*sz;
  #local r = 0.2*sz;
  union {
    cylinder{ <0,0,0>, <0,0,h>, r texture { tinta_B } }
      #if(n = 0)
        sphere { <0,0,h>, 0.6 texture { tinta_A } }
      #else
        sphere{ <0,0,h>, r texture { tinta_B } }
        object{ arvore(n-1,0.7*sz) rotate 27*z rotate 47*x translate h*z }
        object{ arvore(n-1,0.8*sz) rotate 49*z rotate -35*x translate h*z }
      #end
  }
#end

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

arvore(5,5.0)