#! /bin/csh -f
# Last edited on 2000-05-02 15:49:46 by stolfi

# Draws the raw contour and the filtered one, superimposed,
# showing the pairing.

set usage = "$0 PIECE VARIANT CVTYPEA LAMBDAA CVTYPEB LAMBDAB"

set piece = "$1"; shift
set variant = "$1"; shift
set ctypea = "$1"; shift
set banda = "$1"; shift
set ctypeb = "$1"; shift
set bandb = "$1"; shift

if ( $#argv != 0) then
  echo "usage: ${usage}"; exit 1
endif

set curvea = "${ctypea}${banda}"
set curveb = "${ctypeb}${bandb}"
set dir = "${piece}-${variant}"

if ( ${curvea} == ${curveb} ) then 
  echo "same curves, exiting"; exit 0
endif

if ( ${banda} == 000 ) then
  set every = 8
else
  @ every = 8 / ${banda}
  if ( "${every}" == 0 ) then
    set every = 1 
  endif
endif

set filea = "${dir}/${curvea}"
set fileb = "${dir}/${curveb}"
set output = "${dir}/${curvea}-${curveb}"

if ( ( -r ${filea}.flc ) && ( -r ${fileb}.flc ) ) then
  echo "generating ${output}.eps"
  /bin/rm -f ${output}.eps
  /n/gnu/bin/nice PZDrawFiltering \
      -curves ${filea} ${fileb} -extension ".flc" \
      -window ${piece} \
      -output ${output} \
      -filterLambda ${bandb} \
      -drawMatchEvery ${every} \
      -epsFormat
  if ( -r ${output}.eps ) then
    ghostview -openwindows ${output}.eps
  endif
else
  echo "${filea}.flc and/or ${fileb}.flc not found"
endif