// Last edited on 2010-05-16 04:04:04 by stolfilocal
// Caption: Stage.

global_settings { assumed_gamma 2.2 }
#declare eps = 0.001;  // Skosh to keep surfaces from touching.

#declare closeup = false; // Shows close-up view if true; full view if false.
#declare explode = 0.0;   // Explode parts if positive.

background { color rgb <1.000, 1.000, 1.000>  }

#include "pst_axes.inc"
#include "pst_textures.inc"
#include "pst_stage.inc"

#declare scene_type = scene_mask; // Type of sample scene.
#declare max_light_incl = 45;     // Max nominal light inclination.
#declare max_scene_wdt = 200;     // Max X and Y extent of scene.
#declare max_scene_hgt =  50;     // Max Z extent of scene.

#declare stage_foot_hgt = 30;     // Height of stage feet.

#declare stage_handle_pos = stage_plate_szX/2 - 15; // Position of handles.
  
#declare scene = 
  union{
    object{ 
      stage( 
        stage_foot_hgt, stage_handle_pos, 
        max_scene_wdt, max_scene_hgt, scene_type, max_light_incl, 
        explode
      )
    }
  }

#declare scene_min = min_extent(scene);
#declare scene_max = max_extent(scene);
#declare scene_rad = vlength(scene_max - scene_min)/2;
#declare scene_ctr = (scene_min + scene_max)/2;

object{ scene }
object{ axes(1.5,600) no_shadow }

#if (closeup)
  // For debugging. Edit these as needed.
  #declare viewElev = 20.0;
  #declare viewDist = 600.0;
  
  // Close-up of foot:
  // #declare viewAzim = 135.0;
  // #declare viewRadius = 60.0;
  // #declare viewCenter = < -280, -280, stage_foot_hg >;
  
  // Close-up of handle:
  #declare viewAzim = 0.0;
  #declare viewRadius = 80.0;
  #declare viewCenter = < 280, 0, stage_foot_hgt >;
#else
  // For production figures. Edit with care.
  #declare viewAzim = 75.0;
  #declare viewElev = 55.0;
  #declare viewDist = 8*scene_rad;
  #declare viewRadius = 1.50*scene_rad;
  #declare viewCenter = scene_ctr;
#end

#include "pst_camlight.inc"

camlight(viewCenter, viewAzim, viewElev, viewDist, viewRadius, z, 2, 1.00)