// Last edited on 2010-05-16 04:05:30 by stolfilocal
// Caption: Gauge with baffle cup, pedestal, visibility cone, cutaway

global_settings { assumed_gamma 2.2 }
#declare eps = 0.001;  // Skosh to keep surfaces from touching.

#declare closeup = false; // Shows close-up view if true; full view if false.
#declare explode = 0.0;   // Explodes the parts if > 0.
#declare cutaway = true;  // Cutaway view if true.
#declare viscone = true;  // Show total visibility cone.

background { color rgb <1.000, 1.000, 1.000>  }

#include "pst_textures.inc"
#include "pst_light_gauge.inc"

#declare scene = 
  intersection{
    object{ gauge_in_baffle(110.0,explode,viscone,cutaway) }
    plane{ x,0
      texture{ tx_cutaway }
    }
  }

#declare scene_min = min_extent(scene);
#declare scene_max = max_extent(scene);
#declare scene_rad = vlength(scene_max - scene_min)/2;
#declare scene_ctr = (scene_min + scene_max)/2;

object{ scene }

#if (closeup)
  // For debugging. Edit these as needed.
  #declare viewAzim = 110.0;
  #declare viewElev = 30.0;
  #declare viewDist = 600.0;
  #declare viewRadius = 40.0;
  #declare viewCenter = scene_ctr;
#else
  // For production figures. Edit with care.
  #declare viewAzim = 30.0;
  #declare viewElev = 30.0;
  #declare viewDist = 600.0;
  #declare viewRadius = 1.15*scene_rad;
  #declare viewCenter = scene_ctr - 10*y;
#end

#include "pst_camlight.inc"

camlight(viewCenter, viewAzim, viewElev, viewDist, viewRadius, z, 2, 1.00)