#! /usr/bin/gawk -f

# Scans a file and outputs a "sed" file that 
# fixes any "?" symbols 

BEGIN { 
  split("", fw); split("", delicate);
  # characters that need to be protected in sed patterns:
  delchars = "^$/\\&*.+[]|";
  for(i=1;i<=length(delchars);i++)
    { delicate[substr(delchars,i,1)] = true }
  lenw = 5;
  lenl = int(lenw/2);
  lenr = lenw-1-lenl;
  padl = ""; for(i=0;i<lenl;i++) padl = (padl "\015");
  padr = ""; for(i=0;i<lenr;i++) padr = (padr "\012");
  if (MINOCC == 0) MINOCC = 10
}

function context(w)
{
  # Assumes length(w) = lenw
  return (substr(w,1,lenl) "?" substr(w,lenl+2,lenr))
}

function tally(w, tb)
{
  if (w in tb) { tb[w]++ } else { tb[w] = 1 }
}

function protect(s)
{
  # Quotes sed-special characters in s.
  # Assumes that \015 = beginning-of-line and \012 = end-of-line.
  r = ""; lens = length(s);
  for(i=1;i<=lens;i++)
    { si = substr(s,i,1);
      if (si in delicate) 
        { r = (r "\\" si) }
      else if (si == "\015")
        { if (r == "") r = (r "^") }
      else if (si == "\012")
        { if (i == lens) r = (r "$") }
      else
        { r = (r si) }
    }
  return r
}

function sedpattern(c)
{
  # Makes a "sed" pattern out of a context
  return protect(c)
}

function sedreplacement(w)
{
  # Makes a "sed" replacement string out of a substring
  return (protect(gensub(/[\015\012]/, "", "g", w)))
}

function prules(fw)
{
  split("", fc);
  # Tally occurrences of each context:
  for (w in fw)
    { c = context(w);
      if (!(c in fc)) fc[c] = 0;
      fc[c] += fw[w]
    }
  # Find majoritary middle char for this context:
  for (w in fw)
    { c = context(w);
      if ((fc[c]>=MINOCC) && (2*fw[w] > fc[c]))
        { # printf "# %6d %6d\n", fw[w], fc[c];
          printf "s/%s/%s/g\n", sedpattern(c), sedreplacement(w) 
        }
    }
}

/./ {
  m = length($0);
  lin = (padl ($0) padr);
  for(i=1;i<=m;i++)
    { w = substr(lin,i,lenw);
      tally(w, fw)
    } 
}

/^$/ { next; }

END {
  prules(fw)
  exit 0;
}