#! /bin/csh -f
# Last edited on 2002-03-29 14:20:55 by stolfi

set cmd = "$0"; set cmd = "${cmd:t}"
set usage = "${cmd} [DOALLSCRIPT...]"

set scripts = ( $* )
if ( $#scripts == 0 ) then
  set scripts = ( `ls do-all-*[a-z]` )
  set showrest = 1
else
  set showrest = 0
endif

# Enmerate all numbered directories:

ls -d [0-9]*[0-9] | sort > .ALL.dirs

# Enumerate all directories of each major theme:

set dlists = ( )
foreach f ( ${scripts} )
  set name = `echo $f | sed -e 's/^do-all-//'`
  set dlist = ".${name}.dirs"
  echo '=== '"${name}"' ==='
  cat $f \
    | egrep -v '^[#]' \
    | grep 'run-povray' \
    | sed -e 's:^.*\([0-9][0-9]-[0-9][0-9]-[0-9][0-9]-[0-9][0-9][0-9][0-9][0-9][0-9]\).*$:\1:' \
    > ${dlist}
  set dirs = ( `cat ${dlist}` )
  @ n = $#dirs - 1
  foreach dir ( ${dirs[1-$n]} )
    xv $dir/p.gif &
  end
  xv ${dirs[$#dirs]}/p.gif
  set dlists = ( ${dlists} ${dlist} )
end

# Diplay unclassified images:

if ( $showrest ) then
  cat ${dlists} | sort | uniq | bool 1-2 .ALL.dirs - > .REST.dirs
  if ( ! ( -z .REST.dirs ) ) then
    foreach dir ( `cat .REST.dirs` )
      xv $dir/p.gif &
    end
  endif
endif

  
