// MC930 - Exemplo de main.pov para o trabalho final
// Last edited on 2000-12-14 09:07:40 by mc726

// MONUMENTO

#include "colors.inc"

#declare centro_do_monumento = < 0.00, 0.00, 1.50 >;

#declare parte_predio =
superellipsoid {
    < 0.02, 0.10 >
    pigment { White }
    scale < 3.50, 3.50, 2.00 >
  }

#declare parte_miolo =
  prism {
    conic_sweep
    linear_spline
    0, // height 1
    1, // height 2
    5, // the number of points making up the shape...
    <4,4>,<-4,4>,<-4,-4>,<4,-4>,<4,4>
    rotate < 180, 0, 0 >
    translate < 0.00, 1.00, 0.00 >
    scale < 1, 4, 1 >
    pigment { color White }
  }

#declare dif_miolo =
  box {
    < -4.00, -4.00, 0.50>,
    < 4.00, 4.00, 2.15 >
    pigment { color White }
  }

#declare monumento =
  union {
    object {
      parte_predio
      translate < 0.00, -4.50, 0.50 >
    }
    object {
      parte_predio
      translate < 0.00, 4.50, 0.50 >
    }
    difference {
      difference {
        object {
          parte_miolo
          rotate < 90.00, 0.00, 0.00 >
          translate < 0.00, 0.00, 0.75 >
        }
        object {
          dif_miolo
        }
      }
      object {
         dif_miolo
         translate  < 0.00, 0.00, 3.00 >
      }
    }
  }


// PAVIMENTO

#declare pavimento =
  plane {z,0
    texture {
      pigment {
        color < 0.00, 1.00, 0.00 >
      }
      finish {
        ambient 0.10
        diffuse 0.90
      }
      normal {
        granite 0.50
      }
    }
    scale 10
  }


// FUNDO

background{ color rgb < 0.90, 0.92, 0.95 > }

// EIXOS

#declare eixos_cartesianos =
  union {
    cylinder { <0,0,0>, <10,0,0>, 0.02 pigment { color rgb <1,0,0> } }
    cylinder { <0,0,0>, <0,10,0>, 0.02 pigment { color rgb <0,1,0> } }
    cylinder { <0,0,0>, <0,0,10>, 0.02 pigment { color rgb <0,0,1> } }
  }

object { eixos_cartesianos }
object { pavimento }
object { monumento }

// CÂMARA

#declare centro_da_cena = centro_do_monumento;
#declare raio_da_cena = 5.0;
#declare direcao_da_camera = vnormalize( < 3, 2, 1 > );

#declare dist_da_camera = 6.0 * raio_da_cena
#declare pos_da_camera = centro_da_cena + dist_da_camera * direcao_da_camera;
camera {
  location  pos_da_camera
  right     <  -0.64,  0.00,  0.00 >
  up        <   0.00,  0.48,  0.00 >
  sky       z
  look_at   centro_da_cena
}

// ILUMINAÇÃO

#declare direcao_da_luz = vrotate(direcao_da_camera, < 10, 10, 10 >);
#declare intens_da_luz = 2.00;

light_source {
  20 * raio_da_cena * direcao_da_luz
  color rgb intens_da_luz * < 1, 1, 1 >
}