// MC930 - Exemplo de main.pov para o trabalho final
// Created on 2000-12-14 09:07:40 by mc726
// Modified on 2000-12-14 by 970496
// Modified on 2000-12-21 by 970496

// EXERCICIO FINAL
// By Daniel Salles de Araujo Dezembro de 2000
//
// Lago da Praca do Basico - UNICAMP

#include "colors.inc"
#include "textures.inc"

//retirado do stones.inc padrao do Pov-Ray
#declare Pedra = 
texture { 
pigment 
 {granite 
  turbulence 0.6 
  color_map 
   {[0.000, 0.119   color rgbf <0.310, 0.384, 0.420, 0.631> 
                    color rgbf <0.322, 0.369, 0.416, 0.847>] 
    [0.119, 0.322   color rgbf <0.322, 0.369, 0.416, 0.847> 
                    color rgbf <0.424, 0.369, 0.420, 0.549>] 
    [0.322, 0.449   color rgbf <0.424, 0.369, 0.420, 0.549> 
                    color rgbf <0.373, 0.424, 0.518, 0.965>] 
    [0.449, 0.729   color rgbf <0.373, 0.424, 0.518, 0.965> 
                    color rgbf <0.482, 0.573, 0.533, 0.741>] 
    [0.729, 1.001   color rgbf <0.482, 0.573, 0.533, 0.741> 
                    color rgbf <0.310, 0.384, 0.420, 0.631>] 
   } 
 } 
 } 

// Modificado de DMFWood1 do textures.inc
#declare Madeira =  
pigment { 
    wood 
    turbulence 0.04 
    octaves 3 
    scale <0.05, .05, 1> 
    color_map { 
        [0.1 rgb <0.88, 0.60, 0.30>] 
        [0.9 rgb <0.40, 0.30, 0.20>] 
    } 
} 

#declare Cor_de_Pato =  
pigment { 
    agate
    turbulence 0.02 
    octaves 3 
    scale <0.05, .05, 1> 
    color_map { 
        [0.1 rgb <0.88, 0.80, 0.70>] 
        [0.9 rgb <1, 1, 0.95>] 
    } 
} 

#declare Cor_de_Patinho =  
pigment { 
    agate
    turbulence 0.05 
    octaves 3 
    scale <0.05, .05, 1> 
    color_map { 
        [0.1 rgb <0.88, 0.80, 0.10>] 
        [0.9 rgb <1, 1, 0.2>] 
    } 
} 

#declare monumento =
  cone{ <0,0,0>, 1.3
           <0,2.2,0>, 0.3
    texture{ Pedra }
    normal { bumps 0.4 }
  }


// ========================CAMERA ==============================

// Vista do topo
/*
camera {
  location <0,60,0>
  sky       y
  look_at   <0,5,0>
}
*/

camera {
  location  <30,13,15>
  sky       y
  look_at   <0,5,0>
}

  
// ================= PAVIMENTO (GRAMA) ==========================

#declare pavimento=
plane { y, 0
  pigment { color ForestGreen }
  normal { bumps 0.4 scale 0.7 }
  finish { ambient .3 diffuse .7 ambient 0.1 roughness 0.15 }
}

// FUNDO - Retirado do manual do pov-ray com algumas modificaçoes.

sky_sphere {
    pigment {
      gradient y
      color_map {
        [0.000 0.002 color rgb <0.0, 0.2, 1.0>
                     color rgb <0.0, 0.2, 0.1>]
        [0.002 0.200 color rgb <0.0, 0.1, 0.8>
                     color rgb <0.2, 0.2, 0.3>]
      }
      scale 2
      translate -1
    }
    pigment {
      bozo
      turbulence 0.65
      octaves 6
      omega 0.7
      lambda 2
      color_map {
          [0.0 0.1 color rgb <0.85, 0.85, 0.85>
                   color rgb <0.75, 0.75, 0.75>]
          [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                   color rgbt <1, 1, 1, 1>]
          [0.5 1.0 color rgbt <1, 1, 1, 1>
                   color rgbt <1, 1, 1, 1>]
      }
      scale <0.2, 0.6, 0.2>
    }
    rotate -90*x
}

// ============================ ILUMINAÇÃO ================================

light_source {
  <15,15,0>
  color rgb < 1, 1, 1 >
} 
light_source {
  <0,15,-15>
  color rgb < 1, 1, 1 >
}
light_source {
  <-15,15,0>
  color rgb < 1, 1, 1 >
}
light_source {
  <0,15,15>
  color rgb < 1, 1, 1 >
}
light_source {
  <0,15,0>
  color rgb < .8, .8, .8 >
}
light_source {
  <15,4,15>
  color rgb < .8, .8, .8 >
}


// =========================== DECLARACOES ================================
#declare lago=
union {
  difference {
    cylinder { <0,0,0>, <0,0.5,0>, 5.2
      texture { pigment {Gray60} }
    }
    cylinder { <0,-1,0>, <0,1,0>, 5.0 }
  }
  difference {
    cylinder { <0, -1.5, 0>, <0, 0, 0>, 5.1
      texture { pigment { Gray60} }
    }
    cylinder { <0, -2.5, 0>, <0, 0.5, 0>, 5.0 }
  }
  // Fundo (precisa?)
  cylinder { <0, -2, 0>, <0, -1.95, 0>, 5.0 texture {pigment {Gray60} } }

  // Disco externo
  difference {
    cylinder { <0,0,0>, <0, 0.3, 0>, 5.8
    texture {pigment { Gray60} }
    }
    cylinder { <0,-0.1, 0>, <0, 0.4, 0>, 5.6 }
  }

  // Grama
  difference {
    cylinder { <0,0,0>, <0, 0.4, 0>, 5.6
      texture { pigment { ForestGreen} }
      normal { bumps 0.4 scale 0.02 }
    }
    cylinder { <0,-0.1,0>, <0, 0.5, 0>, 5.2 }
  }
  
  // Abaixo: Agua!
  cylinder { <0,-1.95,0>, <0, -0.05, 0>, 4.7 texture { Water } } 

  // cylinder { <0,-1.95,0>, <0, -0.05, 0>, 4.7 texture { pigment { Blue }} } 
}

#declare casa_pato=
difference {
 box {
  <0,0,0>, <2.1,2.1,2.1>
  texture { Madeira }
  hollow
 }
 box { 
  <1.9, 0, 0.6>, <2.2, 0.7, 1.5>
 }
}

#declare pato=
union {
 sphere {
      <0, 0, 0>  2
      scale <2.75, 1, 1>
      translate <0, 2.5, 0>
      texture { Cor_de_Pato }
  }
  sphere {
      <0, 0, 0>  1.5
      translate <-3.5, 5, 0>
      texture { Cor_de_Pato }
   }
  sphere {
        <0, 0, 0> 0.3
        pigment { Black }
        finish { phong 1}
        translate <-4.3, 5.3, -1.4>
   }
  sphere {
        <0, 0, 0> 0.3
        pigment { Black }
        finish { phong 1}
        translate <-4.3, 5.3, 1.4>
   }
  cone { 
    <0,  0, 0>, 0.4
    <-0.52, -0.5, 1.5>, 0.1
    open
    rotate y*-90
    translate <-5, 4.9, 0>
    pigment { Orange }
    finish { phong 1}
   }
}

#declare patinho=
union {
 sphere {
      <0, 0, 0>  2
      scale <2.75, 1, 1>
      translate <0, 2.5, 0>
      texture { Cor_de_Patinho }
  }
  sphere {
      <0, 0, 0>  1.5
      translate <-3.5, 5, 0>
      texture { Cor_de_Patinho }
   }
  sphere {
        <0, 0, 0> 0.3
        pigment { Black }
        finish { phong 1}
        translate <-4.3, 5.3, -1.4>
   }
  sphere {
        <0, 0, 0> 0.3
        pigment { Black }
        finish { phong 1}
        translate <-4.3, 5.3, 1.4>
   }
  cone { 
    <0,  0, 0>, 0.4
    <-0.52, -0.5, 1.5>, 0.1
    open
    rotate y*-90
    translate <-5, 4.9, 0>
    pigment { Orange }
    finish { phong 1}
   }
}


#declare pedra =
blob {
  threshold 0.2
  sphere { <0,0,0>, 1, .3 }
  sphere { <0.4,0,0>, 0.5, .3 }
  sphere { <0,0,0.2>, 0.4, .3 }
  texture { Pedra }
  normal { bumps 0.6 scale 0.2 }
  finish { phong 0.2 }
}

// ================================= PEDRAS ================================

object {
  pedra
  scale 3
  translate <-8, 6, 6>
}
object { 
  pedra
  scale 2.5
  translate <8,6,10>
}
union {
  object { 
    pedra
    scale 3.2
    translate <-7,6,-7>
  }
  object { 
    pedra
    scale 3.2
    translate <-8,6,-6>
  }
}
object { 
  pedra
  scale 3.6
  translate <5,5.9,-3>
}
object { 
  pedra
  scale 2
  translate <10,6.3,-10>
}
object { 
  pedra
  scale 2
  translate <-10,6,0>
}
object { 
  pedra
  scale 2
  translate <1,6.2,13>
}

// lago ================================ LAGO ===============================
object {
  lago
  scale <1, 1, 1> * 4
  translate <0, 1.5*4, 0>
}

// ============================== PIRAMIDE CENTRAL =========================
object {
  monumento
  scale <1, 1, 1> * 4
  translate <0, 1.3, 0> * 4
} 

// Bloco de patos =======================  PATOS ==============================
object { 
  casa_pato
  rotate 45*y
  scale <.7,.7,.7>
  translate < 7, 5.7, 7>
}
object {
  pato
  scale <.3,.3,.3>
  rotate y*120
  translate <10,5,-3>
}
object {
  patinho
  scale <.1,.1,.1>
  rotate y*120
  translate <9, 5.7, -6>
}
object {
  patinho
  scale <.1,.1,.1>
  rotate y*120
  translate <10.75, 5.7, -6>
}

// ============================= GRAMA DO CHAO =============================
object { 
  pavimento 
}

// ===========================================================================