#include "colors.inc"
#include "stones.inc"
#include "textures.inc"
#include "finish.inc"

camera {
   location <40, 4, 20>
   look_at <8, 15, 0>
}
background { color White }
light_source { <0, 50, 0> Yellow }
light_source { <0, 0, 50> White }
light_source { <80, 40, -80> White }


#declare t_prata =
texture {
    pigment { Silver }
    finish {
      ambient .1
      diffuse .4
      specular .3
      roughness 0.001
      reflection .3
      metallic
    }
  }


#declare t_granito =
	texture {
         pigment
         {
            granite
            color_map
            {
               [ 0.0     rgbft <0.3, 0.2, 0.3, 0.0, 0.0> ]
               [ 0.22    rgbft <0.55, 0.56, 0.50, 0.0, 0.0> ]
               [ 1.0     rgbft <0.73, 0.70, 0.60, 0.0, 0.0> ]
            }
            turbulence 0.7
            ramp_wave
         }
         normal
         {
            bumps , 0.1
            scale  0.2
         }
         finish
         {
            ambient 0.5
            diffuse 1.0
            crand 0.25
         }
      }


#declare t_vidro =

   material
   {
      texture
      {
         pigment
         {
            color rgbf <0.4, 0.4, 0.45, 0.9>
         }
         normal
         {
            bumps , 0.2
            scale  <0.5, 0.5, 5.0>
         }
         finish
         {
            ambient 0.1
            diffuse 0.2
            phong 1.0
            phong_size 50.0
            specular 0.9
            roughness 0.06
            reflection 0.15
         }
      }
      interior
      {
         ior 1.1
      }
   }


#declare eixos =
union
{
	cylinder {<-20,0,0>, <20,0,0>, 0.02 pigment { Red }}
	cylinder {<0,-20,0>, <0,20,0>, 0.02 pigment { Green }}
	cylinder {<0,0,-20>, <0,0,20>, 0.02 pigment { Blue }}
}



#declare prisma =
	prism {
		linear_sweep
		linear_spline
		-0.01, 1.01, 4,
		<0,.2>,<0,-.2>,<-.8,0>,<0,.2>    			
 	}

#declare estrela =
difference
{
	cylinder{<0,0,0>,<0,.5,0>, 1 }
	merge
	{
		object { prisma }
		object { prisma rotate <0,90,0> }
		object { prisma rotate <0,180,0> }
		object { prisma rotate <0,270,0> }
	}
	scale <0.6,0.6,0.4>
	rotate <90,0,0>
}

#declare logo =
union
{
	text { ttf "ariali.ttf" "CITIBANK" 0.5, 0}     // Configurar o caminho correto
	object { estrela translate <5.2,0.5,0> }
}

#declare ceu = 
plane { y, 500
    texture {
      pigment { SkyBlue }
      finish { ambient 1 diffuse 0}
     }
     texture {
       pigment {
         bozo
         turbulence .5
         color_map {
           [0 White]
           [1 White filter 1]
         }
       }
       finish { ambient 1 diffuse 0 }
       scale <1000, 250, 250>
	   rotate <75,0,-75>
    }
  }


#declare Janela =
union 
{
        box { <0,0,0>, <1,1,0.1> material { t_vidro } }
        box { <0,0,0>, <0.01,1,0.1> texture{ pigment { Black }}}
        box { <0,0,0>, <1,0.01,0.1> texture{ pigment { Black }}}
        box { <0,1,0>, <1,1-0.01,0.1> texture{ pigment { Black }}}
        box { <1,0,0>, <1-0.01,1,0.1> texture{ pigment { Black }}}
}

#declare coluna =
        box { <0,0,0>, <0.2,1,0.5> texture { t_granito }}

#declare paredeandar =
union
{
        object { Janela }
        object { Janela translate <1,0,0> }
        object { coluna translate <2,0,0> }
        object { Janela translate <2.2,0,0> }
        object { Janela translate <3.2,0,0> }
        object { Janela translate <4.2,0,0> }
        object { coluna translate <5.2,0,0> }
        object { Janela translate <5.4,0,0> }
        object { Janela translate <6.4,0,0> }
        object { Janela translate <7.4,0,0> }
        object { coluna translate <8.4,0,0> }
        object { Janela translate <8.6,0,0> }
        object { Janela translate <9.6,0,0> }
        object { Janela translate <10.6,0,0> }
        object { coluna translate <11.6,0,0> }
        object { Janela translate <11.8,0,0> }
        object { Janela translate <12.8,0,0> }
        object { Janela translate <13.8,0,0> }
        object { coluna translate <14.8,0,0> }
        object { Janela translate <15,0,0> }
        object { Janela translate <16,0,0> }
        object { Janela rotate <0,45,0> translate <17,0,0>}
}


#declare fatiaandar =
union
{
        object { paredeandar }
        object { paredeandar rotate <0, 90, 0> translate <17+(sqrt(2))/2,0,-(sqrt(2))/2>}
        object { paredeandar rotate <0, -90, 0> translate <-(sqrt(2))/2, 0, -17-(sqrt(2))/2>}
        object { Janela rotate <0,-135,0> translate <0,0,-17-sqrt(2)> }
        object { Janela rotate <0,180,0> translate <1,0,-17-sqrt(2)> }
        object { Janela rotate <0,180,0> translate <17,0,-17-sqrt(2)> }
        box { <1,0,-17-sqrt(2)>, <1.2,1,-22> texture { t_granito }}
        box { <16,0,-17-sqrt(2)>, <15.8,1,-22> texture { t_granito }}
        box { <0,0,0>,<0.2,1,-sqrt(2)> texture { t_granito } rotate <0,-45,0> translate <1,0,-22> }
        box { <0,0,0>,<0.2,1,-sqrt(2)> texture { t_granito } rotate <0,-45,0> scale <-1,1,1> translate <16,0,-22> }
        box { <2,0,-22.8>, <15,1,-23> texture { t_granito } }
        
}

#declare Count = 0;
#while (Count < 37)
        object { fatiaandar translate <0, Count, 0> }
        #declare Count = Count+1 ;
#end



//object {logo texture {t_prata} scale 2 translate <-2,0,0>}
//object{ eixos }
object{ ceu }


plane{ y, -4 texture{ pigment { White }}}