#include "colors.inc"
#include "stones.inc"
#include "textures.inc"
#include "finish.inc"

camera {
   location <12, 6, -12>
   look_at <0, 0, 0>
}
background { color White }
light_source { <0, 30, 0> White }
light_source { <0, 0, 30> White }
light_source { <80, 40, -80> White }


#declare t_prata =
texture {
    pigment { Silver }
    finish {
      ambient .1
      diffuse .4
      specular .3
      roughness 0.001
      reflection .3
      metallic
    }
  }


#declare t_granito =
	texture {
         pigment
         {
            granite
            color_map
            {
               [ 0.0     rgbft <0.3, 0.2, 0.3, 0.0, 0.0> ]
               [ 0.22    rgbft <0.55, 0.56, 0.50, 0.0, 0.0> ]
               [ 1.0     rgbft <0.73, 0.70, 0.60, 0.0, 0.0> ]
            }
            turbulence 0.7
            ramp_wave
         }
         normal
         {
            bumps , 0.1
            scale  0.2
         }
         finish
         {
            ambient 0.5
            diffuse 1.0
            crand 0.25
         }
      }


#declare t_vidro =

   material
   {
      texture
      {
         pigment
         {
            color rgbf <0.4, 0.4, 0.45, 0.9>
         }
         normal
         {
            bumps , 0.2
            scale  <0.5, 0.5, 5.0>
         }
         finish
         {
            ambient 0.1
            diffuse 0.2
            phong 1.0
            phong_size 50.0
            specular 0.9
            roughness 0.06
            reflection 0.15
         }
      }
      interior
      {
         ior 1.1
      }
   }


#declare eixos =
union
{
	cylinder {<-20,0,0>, <20,0,0>, 0.02 pigment { Red }}
	cylinder {<0,-20,0>, <0,20,0>, 0.02 pigment { Green }}
	cylinder {<0,0,-20>, <0,0,20>, 0.02 pigment { Blue }}
}



#declare prisma =
	prism {
		linear_sweep
		linear_spline
		-0.01, 1.01, 4,
		<0,.2>,<0,-.2>,<-.8,0>,<0,.2>    			
 	}

#declare estrela =
difference
{
	cylinder{<0,0,0>,<0,.5,0>, 1 }
	merge
	{
		object { prisma }
		object { prisma rotate <0,90,0> }
		object { prisma rotate <0,180,0> }
		object { prisma rotate <0,270,0> }
	}
	scale <0.6,0.6,0.4>
	rotate <90,0,0>
}

#declare logo =
union
{
	text { ttf "arial.ttf" "CITIBANK" .5, 0}
	object { estrela translate <5.2,0.5,0> }
}




object {logo texture {t_prata} scale 2 translate <-2,0,0>}
	



object{ eixos }

sphere{ <0,0,0>, 2 material { t_vidro }}
box { <-.3,-3,-5>,<0,4,0> texture { t_granito scale 4 }}
box { <-.1,-2.5,-4.5>,<.1,3.5,0> material { t_vidro }}

plane{ y, -4 texture{ pigment { White }}}


plane { y, 700
    texture {
      pigment { SkyBlue }
      finish { ambient 1 diffuse 0}
     }
     texture {
       pigment {
         bozo
         turbulence .5
         color_map {
           [0 White]
           [1 White filter 1]
         }
       }
       finish { ambient 1 diffuse 0 }
       scale <1000, 250, 250>
    }
  }