// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-04-12 07:40:53 by stolfi

#include "colors.inc"
#include "stones.inc"
#include "textures.inc"

background { color rgb <0.4, 0.4, 0.9> }

camera {
  location 1.0*<0,5,20> 
  right <0.9, 0, 0> up <0, 0.3, 0>
  look_at <0,0,0>
}

light_source { <10,10,20> color White }
light_source { <10,10,21> color White }



#declare piso =
  box { <1000,-1000,1000>, <-1000, 0, -20> texture {T_Stone17} }

#declare bola_de_ouro =
  sphere { <0.5, 1.7, 0.75>, 0.3 texture {Gold_Metal} }

#declare meteorito =
  difference {
    sphere { <-0.5, 1.2, 0.75>, 0.3 scale <1, 1.5, 1> }
    torus { 0.3, 0.1 translate <-0.5, 1.8, 0.75> }
    texture {T_Stone14}
  }

#declare bastao_do_poder =
  union {
    cylinder { <-0.5, 1.6, -0.75>, <+0.5, 1.6, -0.75>, 0.2 }
    sphere { <-0.5, 1.6, -0.75>, 0.2 }
    sphere { <+0.5, 1.6, -0.75>, 0.2 }
    texture {Silver_Metal}
  }

#declare perna_mesa =
  box { <0.2, 0, 0.2>, <-0.2, 1, -0.2> }

#declare tampo_mesa =
  box { <1.0, 1.0, 1.5>, <-1.0, 1.4, -1.5> }

#declare mesa =
  union {
    object { tampo_mesa }
    object { perna_mesa translate <+0.8, 0, +1.3> }
    object { perna_mesa translate <+0.8, 0, -1.3> }
    object { perna_mesa translate <-0.8, 0, +1.3> }
    object { perna_mesa translate <-0.8, 0, -1.3> }
    texture {Tan_Wood}
  }

#declare prateleira =
  union {
    object {mesa}
    object {bola_de_ouro}
    object {meteorito}
    object {bastao_do_poder}
  }



union {
  object { piso }

  #declare i = 0;
  #while (i < 15)
    #declare j = 0;

    #while (j < 15)
      object { prateleira translate <6-i, 0, 5-j> }
      #declare j = j+5;
    #end

    #declare i = i+3;
  #end
}