// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-10-15 00:36:03 by stolfi

// ======================================================================
// CÂMERA 

#declare ctr = < 0.00, 0.00, -3.50 >;
#declare camdir = < 48.00, -24.00, 12.00 >;

camera {
  location  ctr + 0.90*camdir   // Posição do observador.
  right     -0.60*x             // Largura RELATIVA da imagem.
  up        0.80*y              // Altura RELATIVA da imagem.      
  sky       z                   // Qual direção é "para cima"?
  look_at   ctr      // Para onde a câmera está apontando.
} 

// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.



// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +20.0, -50.0, +70.0 >             // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >     // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, +10.0, +15.0 >             // Posição da lâmpada.
  color rgb 0.6 * < 1.00, 1.00, 1.00 >     // Intensidade e corda luz.
} 


// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

// ======================================================================
// CORES USADAS
// ======================================================================
 
#declare bgcolor =
  texture {
    pigment { color rgb < 0.75, 0.80, 0.85 > }
    finish { diffuse 0.8 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare branco = 
  texture {
    pigment { color rgb < 1.00, 1.00, 1.00 > }
    finish { diffuse 0.8 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare azul = 
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.8 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare preto = 
  texture {
    pigment { color rgb < 0.00, 0.00, 0.00 > }
    finish { diffuse 0.8 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare laranja = 
  texture {
    pigment { color rgb < 1.00, 0.70, 0.00 > }
    finish { diffuse 0.8 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  

// ======================================================================
// FORMAS USADAS
// ======================================================================

#declare cabeca =
  sphere {
    <0.00, 0.00, 0.00>, 3.00
    texture {branco}
    translate <0, 0, 4>
  }

#declare pescoco =
  cylinder {
    <0.00, 0.00, +2.00>,
    <0.00, 0.00, -2.00>,
    1.0
    texture {branco}
  }

#declare corpo =
  union {
	 object {cabeca}		
	 object {pescoco}
        }	
		


#declare calca =
  cylinder {
	<0.00, -1.00, +0.00>,
	<0.00, -1.00, -15.00>,
	2.0
	texture {laranja}
	rotate -10*x
	}
 
#declare corte = 
  sphere {
	 <0.00, -26.00, -0.00>, 25.00
	 texture {laranja}
  }
		
#declare perna_d =
  difference { 
	object {calca}
	object {corte}
	}

#declare perna_e =
  object {perna_d scale <1,-1,1>}  



#declare torax =
  box {
	<+1.00, -4.00, -6.00>
	<-1.00, +4.00, +5.00>
	texture {azul}
 }



#declare braco =
  cylinder {
	<0.00, 0.00, +0.00>,
	<0.00, 0.00, -7.50>,
	1.0
	texture {azul}
	rotate -45*x
	translate <0.00, -4.00, +4.50>
	}

#declare ante_braco =
  cylinder {
	<0.00, 0.00, +0.00>,
	<0.00, 0.00, -5.50>,
	1.0
	texture {azul}
	translate <0.00, -8.50, 0.00>
	}


// ======================================================================
// CENA!
// ======================================================================


object {corpo translate <0,0,7>}

object {perna_d translate <0, 0, -6>}
object {perna_e translate <0, 0, -6>}

object {torax}

object {braco}
object {ante_braco}