// Last edited on 2003-10-22 04:12:23 by stolfi

global_settings { max_trace_level 10 }

// ======================================================================
// CÂMERA

#declare ctr = < 0.00, 15.00, 0.00 >;
#declare camdir = < -15.00, 12.00, 80.00 >;

camera {
  location  ctr + 0.80*camdir  // Posição do observador.
  right     -1.0*x             // Largura RELATIVA da imagem.
  up        0.75*y             // Altura RELATIVA da imagem.
  sky       y                  // Qual direção é "para cima"?
  look_at   ctr     // Para onde a câmera está apontando.
}
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
    10 * < +15.0, +60.0, +100.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

light_source {
    10 * < -80.0, +20.0, +30.0 >              // Posição da lâmpada.
  color rgb 0.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

// ======================================================================
// DESCRIÇÃO DA CENA

background{ color rgb < 0.75, 0.85, 0.95 > }

#declare cor_cristal = < 0.9, 0.9, 0.9 >;

#declare tx_cristal =
   texture {
      finish {
        ambient 0.1 diffuse 0.1
        reflection 0.25
        specular 1 roughness 0.001
      }
     pigment { color cor_cristal filter 1 }
   }

#declare cor_metal = < 0.70, 0.70, 0.70 >;

#declare tx_metal =
   texture {
      pigment { rgb cor_metal }
        finish {
          ambient 0.05 diffuse 0.05
          reflection cor_metal
          specular 0.20 roughness 0.05
        }
   }

#declare cinza_escuro =
  texture {
    pigment { checker 
      color rgb < 0.75, 0.75, 0.75 >, 
      color rgb < 0.65, 0.65, 0.65 >
      scale 3
    }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare azul =
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare corpo =
  union {
    cylinder {
       < 0, 0, 0 >
       < 0, 20, 0 >
       11
    }
    cone {
       < 0, 20, 0 >
       11
       < 0, 30, 0 >
       0
    }
    texture { tx_cristal }
    interior { ior 1.5 }
  }

#declare topo =
  torus {
    13
    2
    texture { tx_metal }
    translate < 0, 18, 0 >
  }

#declare mastro =
  cylinder {
    < 0, 0, 0 >
    < 0, 10, 0 >
    0.2
    translate < 0, 26, 0 >
    texture { tx_metal }
  }

#declare bandeira =
   box {
     < 0, 0, -0.1 >
     < 4, 3, 0.2 >
     texture { azul }
   }

#declare porta =
   box {
     < 0, 0, -1 >
     < 6, 6, 2 >
     translate < -3, 0, 11 >
     texture { tx_metal }
   }

#declare piso =
   plane {
     < 0, 1, 0 >
     0
     translate < 0, -0.05, 0 >
     texture { cinza_escuro }
   }

object { corpo }
object { topo }
object { mastro }
object {
  bandeira
  translate < 0, 33, 0>
}
object {
  bandeira
  translate < 0, 30, 0>
  rotate 150*y
}
object { porta }
object { piso }