// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-10-22 04:16:43 by stolfi

global_settings { max_trace_level 10 }

// ======================================================================
// CÂMERA 

#declare ctr = <  0.00, -0.50, 1.00 >;
#declare camdir = <  4.00, 8.00, 1.00 >;

camera {
  location  ctr + 0.65*camdir  // Posição do observador.
  right     -1.00*x
  up        0.75*y
  sky       z
  look_at   ctr  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 1, 1, 1 > }

#declare cor_cristal = <0.70, 0.70, 0.90>;
#declare tx_cristal =
texture{
   finish{
	ambient 0.1 diffuse 0.1
	reflection 0.25
	specular 1 roughness 0.001	
	}
   pigment {color cor_cristal filter 1}
}

#declare espelho_1 = <0.6,0.6,0.6>;
#declare tx_esp_1 =
   texture{
      pigment{rgb espelho_1}
      finish{
         ambient 0.05 diffuse 0.05
	 reflection espelho_1
	 specular 0.20 roughness 0.05
      }
   }

#declare espelho_ouro = <0.8,0.7,0.50>;
#declare tx_esp_ouro =
   texture{
      pigment{rgb espelho_ouro}
      finish{
         ambient 0.05 diffuse 0.05
	 reflection espelho_ouro
	 specular 0.20 roughness 0.05
      }
   }

#declare espelho_2 = <0.9,0.3,0.3>;
#declare tx_esp_2 =
   texture{
      pigment{rgb espelho_2}
      finish{
         ambient 0.05 diffuse 0.05
	 reflection espelho_2
	 specular 0.20 roughness 0.05
      }
   }
#declare tinta_base = 
   texture{
    pigment { color rgb < 1, 1, 1 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
	}

#declare chao =
  plane { <0, 0, 1>, 0
    pigment {color rgb<1,1,1>
    }
  }

#declare pilar =
	cylinder{
	<0,0,0>,
	<0,0,0.6>,
	0.6
	texture {tx_esp_1}
	interior {ior 1.5}
	}

#declare casa =	
	box{
	<-2,-1,0.6>,
	<2,1,1.8>
	texture {tx_cristal}
	}

#declare bola =
	sphere{
	<1.5,0,0.3>,
	0.3
	texture {tx_esp_ouro}
	interior {ior 1.5}
	} 

#declare obra =
   torus {
    0.3, 0.2              // major and minor radius
	rotate 90*x
	translate <-1.5,0.0,0.2>
   texture {tx_esp_ouro}
  }

#declare piso1 =	
	box{
	<-2.05,1.00,0.85>,
	<2.05,1.05,0.95>
	texture {tx_esp_2}
	}

#declare piso2 =
object{
	piso1
	scale <1,-1,1>
}

#declare piso3 =
	box{
	<2,-1.05,0.85>,
	<2.05,1.05,0.95>
	texture {tx_esp_2}
	}

#declare piso4 = 
object{
	piso3
	scale <-1,1,1>
}

#declare piso =
   union{
     object{piso1}
     object{piso2}
     object{piso3}
     object{piso4}
   }
// Aqui está a cena, finalmente:

union{
   object {chao}
   object {pilar}
   object {casa}  
   object {bola}
   object {obra}
   object {piso}
   object {piso
    translate z*0.3 
   }
   object {piso
    translate z*0.6 
   }
}