// Last edited on 2003-10-21 23:05:59 by stolfi
// ======================================================================
// CÂMERA 

global_settings { max_trace_level 10 }

#declare ctr = < 0.00, 0.00, 2.00 >;
#declare camdir = < 3.00, 18.00, 8.00 >;

camera {
  location  ctr + 0.75*camdir  // Posição do observador.
  right     -1.00*x
  up        0.75*y
  sky       z                      // Qual direção é "para cima"?
  look_at   ctr  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  100 * < +40.0, +20.0, +20.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  100 * < -10.0, +30.0, +20.0 >              // Posição da lâmpada.
  color rgb 0.6 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

//fundo:
background { color rgb < 0.75, 0.80, 0.85 > }

//texturas:
#declare tinta_Azul = < 0.00, 0.00, 1.00 >;

#declare tinta_Amarela = < 1, 1, 0>;

#declare tinta_Prata = < 1, 1, 1>;

#declare metal_Azul =
  texture {
    pigment { rgb tinta_Azul }
    finish {
      ambient 0.05 diffuse 0.05 reflection tinta_Azul specular 0.2 roughness 0.05
    }
  }

#declare metal_Prata =
  texture {
    pigment { rgb tinta_Prata }
    finish {
      ambient 0.05 diffuse 0.05 reflection tinta_Prata specular 0.2 roughness 0.05
    }
  }

#declare metal_Amarelo =
  texture {
    pigment { rgb tinta_Amarela }
    finish {
      ambient 0.05 diffuse 0.05 reflection tinta_Amarela specular 0.2 roughness 0.05
    }
  }

#declare transp_Amarelo =
  texture {
    finish {
      ambient 0.1 diffuse 0.1 reflection 0.25 specular 1 roughness 0.001
    }
    pigment { color tinta_Amarela filter 1 }
  }

//objetos:
#declare chao = 
  plane { <0,0,1>, 0
    pigment { checker color rgb < 1.00, 1.00, 1.00 >, color rgb <.25, .25, .25> scale 2}  /* branco e cinza */
    finish { ambient 0.3 diffuse 0.7 }
  }  

#declare base =
  difference {
    difference {
      sphere { 
        <0,0,0>, 4
      }
      plane { 
        <0,0,1>, 0 
      }
    }
    cylinder {
      <0, 4, 0>,
      <0,-4, 0>
      1.0
    }
    texture { metal_Azul }
  }

#declare torre1 =
  cylinder {
    <-3,0,0>,
    <-3,0,6>
    1.0
    texture { transp_Amarelo }
    interior { ior 1.2 }
  }

#declare torre2 =
  object {
    torre1
    scale <-1.00, 1.00, 1.00>
  }

#declare anel1 =
  torus {1, 0.5
    rotate 90*x
    translate <-3, 0, 5>
    texture { metal_Prata }
  }

#declare anel2 =
  object {
    anel1
    scale <-1.00, 1.00, 1.00>
  }

#declare topo1 =
  cone {
    <-3,0,6>, 1.0
    <-3,0,7>, 0
    texture { metal_Amarelo }
  }

#declare topo2 =
  object {
    topo1
    scale <-1.00, 1.00, 1.00>
  }

// ========================================================================
// CENA

union {
  object { chao }
  object { base }
  object { torre1 }
  object { torre2 }
  object { anel1 }
  object { anel2 }
  object { topo1 }
  object { topo2 }
}