// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-07-31 12:50:37 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  10.00, 0.00, 0.00 >  // Posição do observador.
  right     < -0.60, 0.00, 0.00  >   // Largura RELATIVA da imagem.
  up        <  0.00, 0.00, 0.80  >   // Altura RELATIVA da imagem.      
  sky       <  0.00, 0.00, 1.00  >   // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 2.00 >   // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}


// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.0, 0.0, 0.30 > }
  
#declare pneu =
union {
  cylinder { <0.4,0,0>, <-0.2,0,0>, 1.2 
    pigment { color rgb < 0.00, 0.00, 0.00 > }
  }
  torus { 0.9,0.3
    rotate 90*z
    translate <0.4,0,0>
    pigment { color rgb < 0.00, 0.00, 0.00 > }
  }
  cylinder { <0.3999,0,0>, <0.4001,0,0>, 0.6
    pigment { color rgb < 0.50, 0.50, 0.50 > }
  }
}

#declare prato =
difference {
  cylinder { <0.6,0,0>, <-0.2,0,0>, 1.2 
    pigment { color rgb < 0.00, 0.00, 0.00 > }
  }
  cone { <0.601,0,0>, 1.2  <0.4,0,0>, 0.6 }
  pigment { color rgb < 0.95, 0.95, 0.95 > }
}

#declare fundo =
plane {
  <1,0,0>, -1
  pigment { color rgb <0.7,1,0.7> }
}

#declare tudo =
union {
  object {pneu}
  object {prato rotate 180*z}
}

#declare texto =
text {
  ttf "arial.ttf"
  "Fome Zero"
  0.15, 0
  rotate 90*x
  rotate 90*z
  translate <-2,-2.5,2>
}

object { fundo }
object { tudo
  rotate 180*clock*z
}
#if (clock > 0.8)
  object {texto
    translate <1.0,0,0>
  }
#end