// Last edited on 2003-10-22 13:48:08 by stolfi

// ======================================================================
// CÂMERA

#declare ctr = <  0.00, 0.00, 0.00 >;
#declare camdir = <  0.00, 0.00, 20.00 >;

camera {
  location ctr + 1.20*camdir
  right    -1.00*x
  up       0.75*y
  sky      y                          // Qual direção é "para cima"?
  look_at  ctr
}
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
    10 * < +25.0, +60.0, +100.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

light_source {
    10 * < -55.0, +60.0, +100.0 >              // Posição da lâmpada.
  color rgb 0.6 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

background { color rgb < 0.5, 0.9, 0.7 > }

// ======================================================================
// DESCRIÇÃO DA CENA

#declare verde25 =
  texture {
    pigment { color rgb < 0.00, 0.25, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare branco =
  texture {
    pigment { color rgb < 1.00, 1.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare corpo_galao =
  difference {
    difference {
      box {
        < 0, 0, 0 >
        < 10, 10, 2 >
      }
      box {
        < 0, 0, -0.1 >
        < 5, 5, 2.1 >
        rotate 45*z
        translate < 0, 7, 0 >
      }
    }
    box {
      < 5, 7, -0.1 >
      < 9, 9, 2.1>
    }
    texture { verde25 }
    translate < 0, -5, 0 >
    scale < 0.5, 0.5, 0.5 >
  }


#declare bico_galao =
  union {
    cylinder {
      < 0, 0, 1 >
      < 0, 2, 1 >
      1
    }
    cylinder {
      < 0, 2, 1 >
      < 0, 3, 1 >
      2
    }
    texture { verde25 }
    rotate 45*z
    translate < 2, 8, 0 >
    translate < 0, -5, 0 >
    scale < 0.5, 0.5, 0.5 >
  }    

#if (clock<0.2)
  #declare texto="Formula Zero!";
#else
  #if (clock<0.4)
     #declare texto="Na formula 1,";
  #else
    #if (clock<0.6)
       #declare texto="Eh preciso saber quando abastecer!";
    #else
      #if (clock<0.8)
         #declare texto="Chegou a hora de abastecer ...";
      #else
         #declare texto="... os famintos do Brasil!";
      #end
    #end
  #end
#end

#declare legenda =
  text {
    ttf "arial.ttf"
    texto
    0.15, 0
  }

object {
  legenda
  texture { branco }
  translate < -9, 5, 0 >
}

union {
  object { corpo_galao }
  object { bico_galao }
  rotate -180*clock*y
  translate < 4, -4, 0 >
  translate < -10*clock, 0, 0 > 
}