// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-10-23 01:19:19 by stolfi

// ======================================================================
// CÂMERA 

#declare ctr = < 7.00, 4.00, 0.00 >;
#declare camdir = < 0.0, 20.0, 80.0 >;

camera {
  location ctr + 0.80*camdir
  right    -1.00*x
  up       0.75*y
  sky      y                      // Qual direção é "para cima"?
  look_at  ctr
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +30.0, +10.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < -20.0, +10.0, +50.0 >              // Posição da lâmpada.
  color rgb 0.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.0, 0.0, 0.5 > }

#declare raio = 2.000;

#declare tinta_B = 
  texture {
    pigment { color rgb < 0.90, 0.90, 0.90 > }
    finish { diffuse 0.9 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_R = 
  texture {
    pigment { color rgb < 0.70, 0.0, 0.0 > }
    finish { diffuse 0.9 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare preto =
  texture {
    pigment { color rgb < 0.3, 0.3, 0.3 > }
    finish { diffuse 0.9 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare logo =
  text {
    ttf "arial.ttf"
    "Fome Zero"
    4.0, 0
    scale <4,4,4>
    texture { tinta_B }
  }


#declare c1 =   
  cylinder {
    < 0.0, 0.0, 0.0 >,
    < 0.0, 6.0, 0.0 >,
    1.0
    texture { tinta_B }
  }    

#declare c2 =   
  cylinder {
    < 0.0, -1.0, 0.0 >,
    < 0.0, 7.0, 0.0 >,
    0.8
    texture { tinta_B }
  }

#declare c3 =   
  cylinder {
    < 0.0, 0.0, 0.0 >,
    < 0.0, 12.0, 0.0 >,
    0.5
    texture { tinta_B }
  }  
    
#declare b1 =
  box {
    <-1.6, -1.0, 0.0>,
    <1.6, 7.0, 2.0>
    texture { tinta_B}
  }
  
#declare b2 =
  box {  
    <0, 0.0, -1.0>,
    <9, 6.0,  1.0>
    texture { tinta_B}
  }
  
#declare Ban =
  difference {
     difference { 
        object { c1 }
        object { c2 }
     }
     object { b1 }
  }  
    
#declare Bandeira =
  union {  
      intersection {
        union {
          object { Ban scale -1*z translate -1.8*x }
          object { Ban }
          object { Ban scale -1*z translate 1.8*x }
          object { Ban translate 3.6*x }
          translate clock*x 
          scale 2*x
        }
        object { b2 }
        translate 6*y
    }
    object {c3}
  } 

#declare braco =   
  cylinder {
    < 0.0, 0.0, 0.0 >,
    < 6.0, 0.0, 0.0 >,
    1.0
    texture { tinta_R }
  }  
  
#declare cotovelo =
  sphere {
    < 7.00, 0.00, 0.00 >, 1.5
    texture { tinta_R }
  }           
    
#declare tronco = 
  cylinder {
    < 0.0, 10.0, 0.0 >,
    < 0.0, 0.0, 0.0 >,
    4.0
    texture { tinta_R }
  }  

#declare bracao =
  union {
    object { cotovelo translate <-6,0,0>}
    object { braco }
    object { cotovelo }
    union {
      object { braco }
      object { cotovelo translate <0,0,0>}
      rotate -15*z
      translate <8,0,0>
    }
    rotate -60*z
    translate <4,9,0>  
  }

#declare bracaos =
  union {
    object { cotovelo translate <-6,0,0>}
    object { braco }
    object { cotovelo }
    union {
      object { braco }
      object { cotovelo translate <0,0,0>}
      object { Bandeira translate <7,0,0>}
      rotate <0, -20*clock, -15>
      translate <8,0,0>
    }
    rotate -60*z
    rotate 20*clock*z translate <4,9,0>
      
  }  
    
#declare perna =
  union {
    object { cotovelo translate <-6,0,0>}
    object { braco }
    object { cotovelo }
    union {
      object { braco }
      object { cotovelo translate <0,0,0>}
      rotate -15*z
      translate <8,0,0>
    }
    rotate -60*z
    translate <2,-1,0>  
  }  
          
#declare corpo =
  union {
    object { tronco }
    object { bracaos translate <-4,-9,0> rotate 20*clock*z translate <4,9,0>}
    object { bracao scale -1*x }
    object { perna }
    object { perna scale -1*x }
  }
    
    
#declare cab =
  sphere {
    < 0.00, 0.00, 0.00 >, 3.00 
    texture { tinta_R }
  } 

#declare viseira = 
  cylinder {
    <  6.0, 1.0, 2.0 >,
    < -6.0, 1.0, 2.0 >,
    2.0
    scale 2*z
    texture { preto }
  }
    
#declare cabeca =
  union {
    difference {
      object { cab }
      object { viseira }
    }
    intersection {
      object { viseira }
      object { cab texture {preto }}
    }
    translate <-2,13,0>
  }


union {
  object { cabeca translate <2,1,0>}
  object { cotovelo translate <-7,10,0>}
  object { corpo translate <0,0,0>}
  object { logo translate 20*y}
  //object { Bandeira }
}