// ======================================================================
// CÂMERA

camera {
  location  < 10.00, 18.00, 60.00 >  // Posição do observador.
//  location  <  60.00, 0.00, 0.00 >  // Posição do observador.
  right     -1.0*x                     // Largura RELATIVA da imagem.
  up        0.75*y                     // Altura RELATIVA da imagem.
  sky       y                          // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >     // Para onde a câmera está apontando.
}
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
    10 * < +15.0, +30.0, +20.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

// ======================================================================
// DESCRIÇÃO DA CENA

#declare verde25 =
  texture {
    pigment { color rgb < 0.03, 0.25, 0.03 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare marrom =
  texture {
    pigment { color rgb < 0.50, 0.50, 0.03 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare branco =
  texture {
    pigment { color rgb < 1.00, 1.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare cor_metal = < 0.90, 0.90, 0.90 >;

#declare tx_metal =
   texture {
      pigment { rgb cor_metal }
        finish {
          ambient 0.05 diffuse 0.05
          reflection cor_metal
          specular 0.20 roughness 0.05
        }
   }

#declare corpo_galao =
  difference {
    difference {
      box {
        < 0, 0, 0 >
        < 10, 10, 2 >
      }
      box {
        < 0, 0, -0.1 >
        < 5, 5, 2.1 >
        rotate 45*z
        translate < 0, 7, 0 >
      }
    }
    box {
      < 5, 7, -0.1 >
      < 9, 9, 2.1>
    }
    texture { verde25 }
    translate < 0, -5, 0 >
    scale < 0.5, 0.5, 0.5 >
  }


#declare bico_galao =
  union {
    cylinder {
      < 0, 0, 1 >
      < 0, 2, 1 >
      1
    }
    cylinder {
      < 0, 2, 1 >
      < 0, 3, 1 >
      2
    }
    texture { verde25 }
    rotate 45*z
    translate < 2, 8, 0 >
    translate < 0, -5, 0 >
    scale < 0.5, 0.5, 0.5 >
  }    

#if (clock<0.2)
  #declare texto="Formula Zero!";
#else
  #if (clock<0.4)
     #declare texto="Na formula 1,";
  #else
    #if (clock<0.6)
       #declare texto="Eh preciso saber quando abastecer!";
    #else
      #if (clock<0.8)
         #declare texto="Chegou a hora de abastecer ...";
      #else
         #declare texto="... os famintos do Brasil!";
      #end
    #end
  #end
#end

#declare legenda =
  text {
    ttf "arial.ttf"
    texto
    0.15, 0
  }

#declare prisma =
  prism {
    linear_sweep
    linear_spline
    0, // sweep the following shape from here ...
    1, // ... up through here
    7, // the number of points making up the shape ...
    <0,19>, <2,16>, <2,10>, <1,8>, <1,0>, <0,0>, <0,19>
    texture { tx_metal }
  }


#declare late = 
  lathe {
    linear_spline
    6,
    <0,0>, <0,1>, <2,2>, <2,9>, <1,10>, <0,10>
    texture { marrom }
    finish {
      ambient .3
      phong .75
    }
  }

#declare faca =
  union {
     object { prisma rotate -90*x }
     object { late translate < 0.8, -1.5,-1> }
  }

object {
  legenda
  texture { branco }
  translate < -9, 5, 0 >
  scale < 3, 3, 3 >
}

union {
  object { corpo_galao }
  object { bico_galao }
  rotate -540*clock*y
  translate < 15-30*clock, -4, 0 > 
}

object {
  faca
  translate < 0, -5, -10 >
}

object {
  faca
  translate < 0, -5, 10 >
}