// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-07-31 12:50:37 by stolfi

// ======================================================================
// CÂMERA 
#include "colors.inc"

camera {
  location  <9 - 12*clock,20 - 16*clock, 2.56 - 2*clock >  // Posição do observador.
  right     <-0.6,0,0>                 // Largura RELATIVA da imagem.
  up        <0,0,0.8>                 // Altura RELATIVA da imagem.      
  sky       <0,0,1>                      // Qual direção é "para cima"?
  look_at   <3 - 6*clock,0.00,0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < 1.0, 1.0, 5.0 >              // Posição da lâmpada.
  color rgb 2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < 5.0, 1.0, 1.0 >             // Posição da lâmpada.
  color rgb 2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare cor_borracha = <0.1,0.1,0.1>;
#declare cor_metal = <0.8,0.8,0.8>;
#declare cor_lataria = <1,0.2,0.2>;

#declare tex_borracha = texture {
  pigment {rgb cor_borracha}
  finish { ambient 0.05
	   diffuse 0.05
	   reflection cor_borracha
	   specular 0.1 roughness 0.2
  }

}

#declare tex_metal = texture {
	pigment {rgb cor_metal}
	finish {ambient 0.05
		diffuse 0.05
		reflection cor_metal
		specular 0.2
		roughness 0.05
	}
}

#declare tex_lataria = texture {
	pigment {rgb cor_lataria}
	finish {ambient 0.1
		diffuse 0.5
		specular 0.5
		roughness 0.005
		reflection { rgb cor_lataria }
	}
}

#declare chao = plane {
  z,0
  pigment { color rgb <0.3,0.2,0.05> }
  finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
}

#declare pneu = union {
  torus {
    0.4
    0.16
    texture { tex_borracha }
  }
  cylinder {
    <-0.4,0,0>
    <0.4,0,0>
    0.08
    texture {tex_metal}
  }
  cylinder {
    <0,0,-0.4>
    <0,0,0.4>
    0.08
    texture {tex_metal}
  }
}

#declare lataria = prism {
  linear_sweep
  linear_spline
  -1, // sweep the following shape from here ...
  1, // ... up through here
  4, // the number of points making up the shape ...
  <0,0>, <6,0>, <6,2>, <0,0>
  texture { tex_lataria }
}

#declare slogan =
  text {
    ttf "arial.ttf"
    "FOME ZERO"
    0.05,0
    pigment {Blue}
    rotate -90*x
    rotate 180*y
    scale 0.15
}

#declare prato = union {
  difference {
    cone {
      <0,-0.16,0>, 0.4
      <0,0.16,0>, 0.56
    }
    cone {
      <0,-0.08,0>, 0.3
      <0,0.16,0>, 0.56
    }
  }
  object { slogan translate <0.4,0.16,0> }
  pigment { rgb <0.7,0.7,0.7> }
}

// Aqui está a cena, finalmente:

union {
  object { chao }
  object { lataria translate <4.5 - 9*clock,0,0.56> }
  object { pneu translate <6 - 9*clock,-1.4,0.56> }
  object { pneu translate <9 - 9*clock,-1.4,0.56> }
  object { pneu translate <9 - 9*clock,1.4,0.56> }

#if (clock < 0.9)
  object { pneu translate <6 - 9*clock,1.4,0.56> }
#else
  object { prato translate <6 - 9*clock,1.4,0.56> }
#end
}