// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-07-31 12:50:37 by stolfi

// ======================================================================
// CÂMERA 

#include "colors.inc"
#include "skies.inc"

camera {
  location  <  30.00, 15.00, 2.00 >  // Posição do observador.
  right	<-0.60, 0.00, 0.00>
  up <0.00, 0.00, 0.80>
  sky <0.00, 0.00, 1.00>
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 1, 1, 1 > }

plane { <0, 0, 1>, -0.1
   pigment {rgb <0.3,0.6,1>}
}

sky_sphere {S_Cloud3}

#declare Xinicial = -10;
#declare Yinicial = -10;
#declare espaco = 2;

#declare limx = 50;
#declare limy = 50;

#declare i = 1;

#declare gerador = seed(12382);

//Pontos

#while (i <= limx)
   #declare j = 1;
   #while (j <= limy)
      sphere {
         <Xinicial+i*espaco , Yinicial+j*espaco, 0>,
	 0.1
	 pigment { Yellow }
      }
      
      #declare rand1 = rand(gerador);
      #declare R = rand(gerador); 					// Tom do vermelho
      #declare G = rand(gerador); 					// Tom do verde
      #declare B = rand(gerador); 					// Tom do azul 

      #if (rand1 > 0.5 & i < limx) //Pacote pula na dir. X
         box{
            <Xinicial+i*espaco+rand1*espaco -0.05 , Yinicial+j*espaco -0.05 ,-0.05>,
            <Xinicial+i*espaco+rand1*espaco +0.05 , Yinicial+j*espaco +0.05 ,+0.05>
            pigment {color rgb <R,G,B>}
         }
      #else
         box{
            <Xinicial+i*espaco -0.05 , Yinicial+j*espaco-rand1*espaco -0.05 ,-0.05>,
            <Xinicial+i*espaco +0.05 , Yinicial+j*espaco-rand1*espaco +0.05 ,+0.05>
            pigment {color rgb <R,G,B>}
         }
      #end      
      #declare j = j+1;
   #end
   #declare i = i+1;
#end