// Last edited on DATE TIME by stolfi
// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2000-09-21 20:06:05 by ra002388

background{ color rgb < 0.8, 1, 1 > }

light_source {
  < 0.00, 500.00, 400.00 >
  color rgb 1.2*< 1.00, 1.00, 1.00 >
}

light_source {
  < 0.00, 0.00, 400.00 >
  color rgb 0.7*< 1.00, 1.00, 1.00 >
}

light_source {
  < 0.00, -500.00, 400.00 >
  color rgb 0.5*< 1.00, 1.00, 1.00 >
}

#declare n=6;

#declare ctr = < n*n*1.8, 0.00, 0.00 >;
#declare camDir = < 6, 0, 5>*pow(n,1.8) - < n*n*1.8, 0.00, 0.00 > - 50*y;

camera {
  location   ctr + 0.90*camDir
  right      1.20*x
  up         0.90*y
  sky        y
  look_at    ctr
}


#declare barata = texture {
  pigment { color rgb 1.5*< 0.35, 0.15, 0.0 > }
  finish { diffuse 0.75 specular 0.5 roughness 0.005 ambient 0.1}
}

#declare olho = texture {
  pigment { color rgb < 1, 1, 0.0 > }
  finish { diffuse 0.75 specular 0.5 roughness 0.005 ambient 0.1 }
}

#declare s=seed(2388);

#declare i=0;
#while (i<n)
  #declare j=-1;
  #while (j<2)
  #declare delta=60+60*rand(s);
  #declare gama=70*rand(s);
  #declare beta=-70*rand(s);
  #declare alfa=-60*rand(s);

  #declare perna4 = union {
    sphere {
      <0,0,0>,
      1.5
      texture { barata }
    }
    cone {
      <0,0,0>,1.5
      <0,0,10>,0
      texture { barata }
    }
    rotate delta*x
  }

  #declare perna3 = union {
    sphere {
      <0,0,0>,2
      texture { barata }
    }
    cone {
      <0,0,0>,2
      <0,0,15>,1.5
      texture { barata }
    }
    object { perna4 translate <0,0,15> }
    rotate gama*x
  }

  #declare perna2 = union {
    sphere {
      <0,0,0>,
      2.5
      texture { barata }
    }
    cone {
      <0,0,0>,2.5
      <0,0,15>,2
      texture { barata }
    }
    object { perna3 translate <0,0,15> }
    rotate beta*y
  }

  #declare perna = union {
    sphere {
      <0,0,0>,
      3
      texture { barata }
    }
    cone {
      <0,0,0>,3
      <0,0,20>,2.5
      texture { barata }
    }
    object { perna2 translate <0,0,20> }
    rotate 30*x
    rotate alfa*y
  }
  object { perna scale n/8 translate <i*3*n,0,n*2.3> scale <1,1,j>}
  #declare j=j+2;
  #end
  #declare i=i+1;
#end

union {
  intersection {
    sphere {
      <0,-0.5,0>,1
      scale <n*n*2.4,n*4,n*4>
      translate <n*n*1.5,0,0>
      texture { barata }
    }
    sphere {
      <0,0.5,0>,1
      scale <n*n*2.4,n*4,n*4>
      translate <n*n*1.5,0,0>
      texture { barata }
    }
  }
  sphere {
    <n*n*2.7,n*1.6,n*1.6>,n
    texture { olho }
  }
  sphere {
    <n*n*2.7,n*1.6,-n*1.6>,n
    texture { olho }
  }
  cylinder {
    <n*n*2.4,n*1.6,n*1.6>,
    <n*n*3,n*5,n*3>,
    1
    texture {barata}
  }
  sphere {
    <n*n*3,n*5,n*3>,2
    texture { barata}
  }
  cylinder {
    <n*n*2.4,n*1.6,-n*1.6>,
    <n*n*3,n*5,-n*3>,
    1
    texture {barata}
  }
  sphere {
    <n*n*3,n*5,-n*3>,2
    texture { barata}
  }
}

// Aqui está a cena, finalmente: