// Last edited on 2003-12-07 18:59:02 by stolfi
// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================

#declare ctr = < 0.00, 0.00, 2.00 >;
#declare camDir = < -20.00, 18.00, 4.50 >;

camera {
  location   ctr + 1.05*camDir
  right      -1.00*x
  up         0.75*y
  sky        z
  look_at    ctr
}
 

// ======================================================================
// FONTES DE LUZ

light_source {
  100 * < -2.0, 1.0, 3.0 >              // Posição da lâmpada.
  color rgb 1.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  100 * < -2.0, -1.0, 3.0 >             // Posição da lâmpada.
  color rgb 0.6 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

#include "colors.inc"

background{ color rgb <0.20, 0.25, 0.30> }

// ======================================================================
// DESCRIÇÃO DA CENA 


plane {
  z, -6.0
  pigment { Yellow }
}

#declare angulo = 0;
#declare angulo_final = 359;
#declare angulo_passo = 20;

#declare a1a = 15;
#declare a1b = 35;
#declare a2a = 65;
#declare a2b = 85;
#declare a3a = 45;
#declare a3b = 65;
#declare a4a = 65;
#declare a4b = 85;
#declare dist_dedoa = 25;
#declare dist_dedob = 45;

#declare s = seed(48234234);
#declare a0 = 0;
#declare raio = 6;

#while (angulo <= angulo_final)

#declare a1 = a1a+(a1b-a1a)*rand(s);
#declare a2 = a2a+(a2b-a2a)*rand(s);
#declare a3 = a3a+(a3b-a3a)*rand(s);
#declare a4 = a4a+(a4b-a4a)*rand(s);
#declare dist_dedo = dist_dedoa+(dist_dedob-dist_dedoa)*rand(s);


#declare pe = union {
  cylinder { < 0, 0, 0>, <0, 1.0, 0 >, 0.1
      rotate dist_dedo*z 
      rotate a4*(-x) }
  cylinder { < 0, 0, 0>, <0, 1.0, 0 >, 0.1
      rotate a4*(-x) }

  cylinder { < 0, 0, 0>, <0, 1.0, 0 >, 0.1 
      rotate -dist_dedo*z
      rotate a4*(-x) }
}

#declare ante_pe = union {
  cylinder { <0, 0, 0>, <0, 2, 0>, 0.4 }
  sphere { <0, 0, 0>, 0.4 }

  object { pe
    translate <0, 2, 0>
  }

  rotate a3*(-x)
}

#declare ante_pata = union {
  cylinder { <0, 0, 0>, <0, 3, 0>, 0.4 }
  sphere { <0, 0, 0>, 0.4 }
  

  object { ante_pe
    translate <0, 3, 0>
  }

  rotate a2*(-x)
}

#declare pata = union {
  cylinder { <0, 0, 0>, <0, 3, 0>, 0.4 }
  sphere { <0, 0, 0>, 0.4 }

  object { ante_pata
    translate <0, 3, 0>
  }

  rotate a1*x
  rotate a0*z
}


object { pata
  translate <0, raio, 0>
  rotate angulo*z

  pigment { Turquoise }
}

#declare angulo = angulo + angulo_passo;

#end

sphere { <0, 0, 0>, 6 
  pigment { Green }
}

sphere { <0, 0, 8>, 2
  pigment { Brown }
}