// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-07-31 12:50:37 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  80.00, -20.00, -10.00 >  // Posição do observador.
  right     < -0.60, 0.00, 0.00 >                 // Largura RELATIVA da imagem.
  up        <  0.00, 0.00, 0.80 >                 // Altura RELATIVA da imagem.      
  sky       <  0.00, 0.00, 1.00 >                 // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 10.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e cor da luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e cor da luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare dourado = 
  texture {
    pigment { color rgb<0.90, 0.80, 0.50> }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare eixoX =
  cylinder {
	<0.00, 0.00, 0.00>,
	<100.00, 0.00, 0.00>
	0.50
	texture { 
	  pigment { color rgb <1.00, 0.00, 0.00> } 
	}
  }

#declare eixoY =
  cylinder {
	<0.00, 0.00, 0.00>,
	<0.00, 100.00, 0.00>
	0.50
	texture { 
	  pigment { color rgb <0.00, 1.00, 0.00> }
	}
  }

#declare eixoZ =
  cylinder {
	<0.00, 0.00, 0.00>,
	<0.00, 0.00, 100.00>
	0.50
	texture {
	  pigment { color rgb <0.00, 0.00, 1.00> }
	}	
  }

#declare corpo =
  difference {
    object {
      sphere { 
	<0, 0, 0>, 12 
	texture { dourado }
      }
    }
    object {
	box {
	  <100, -100, 0>
	  <-100, 100, 100>
	}
    }
  }

#declare cabeca =
  sphere {
      <0, 12, -2>, 2
      texture { dourado }
  }

#declare esp = 0.50;
#declare pos = 2.00;
#declare numpernas = 12;

#declare pernas =
  union {
#declare fonte = seed(12345);
#declare i=0;
#while (i<numpernas)

    #if (clock<0.5)
	#declare clockP=2*clock;
    #else
	#declare clockP = 2*(1-clock);
    #end

    #if (mod(i,2)=0)
	#declare ang1 = (-22.5)*clockP*rand(fonte);
    	#declare ang2 = (-45)*clockP*rand(fonte);
    	#declare ang3 = (-67.5)*clockP*rand(fonte);
	#declare ang4 = (-90)*clockP*rand(fonte);
    #else
    	#declare ang1 = ((-22.5)-((-22.5)*clockP))*rand(fonte);
    	#declare ang2 = ((-45)-((-45)*clockP))*rand(fonte);
    	#declare ang3 = ((-67.5)-((-67.5)*clockP))*rand(fonte);
	#declare ang4 = ((-90)-((-90)*clockP))*rand(fonte);
    #end
   

    #declare parte =
        cylinder {
	    <0.00, 0.00, 0.00>,
	    <pos, 0.00, 0.00>
	    esp
	    texture { dourado }
        }


    #declare perna1 = 
      union {
        object { 
	    parte
	    rotate ang1*y
	    translate <pos, 0.00, 0.00>
        }
        object { parte }
      }

    #declare perna2 =
      union {
        object {
	  perna1
	  rotate ang2*y
	  translate <pos, 0.00, 0.00>
        }
        object { parte }
      }

    #declare perna3 =
      union {
        object {
	    perna2
	    rotate ang3*y
	    translate <pos, 0.00, 0.00>
        }
        object { parte }
      }

    #declare perna4 =
        object {
	    perna3
	    rotate ang4*y
        }

    object {
	perna4
	translate 12*x
	rotate ((360/numpernas)*i)*z
    }

    #declare i=i+1;
#end
  }

union{
/*
	object{ eixoX }
	object{ eixoY }
	object{ eixoZ }
*/
	object{ corpo }
	object{ cabeca }
	object { pernas }
	rotate 180*x
}