// ======================================================================
// CÂMERA

camera {
  location  <  0, 0, 100.00 >  // Posição do observador.
  right     -1.0*x                     // Largura RELATIVA da imagem.
  up        0.75*y                     // Altura RELATIVA da imagem.
  sky       y                          // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >     // Para onde a câmera está apontando.
}
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
    10 * < +15.0, +60.0, +100.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

// ======================================================================
// DESCRIÇÃO DA CENA

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare cor_cristal = < 0.9, 0.9, 0.9 >;
#declare cor_cristal2 = < 0.5, 0.5, 0.5 >;

#declare tx_cristal =
   texture {
      finish {
        ambient 0.1 diffuse 0.1
        reflection 0.25
        specular 1 roughness 0.001
      }
     pigment { color cor_cristal filter 1 }
   }

#declare tx_cristal2 =
   texture {
      finish {
        ambient 0.1 diffuse 0.1
        reflection 0.25
        specular 1 roughness 0.001
      }
     pigment { color cor_cristal2 filter 1 }
   }

#declare cor_metal = < 0.30, 0.30, 0.30 >;

#declare tx_metal =
   texture {
      pigment { rgb cor_metal }
        finish {
          ambient 0.05 diffuse 0.05
          reflection cor_metal
          specular 0.20 roughness 0.05
        }
   }

#declare cinza_escuro =
  texture {
    pigment { color rgb < 0.75, 0.75, 0.75 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare azul =
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.03 ambient 0.5 }
  }

#declare base =
  intersection {
    box {
       < -100, -13, -10 >
       < 100, 13, 10 >
      texture { tx_cristal }
      interior { ior 1.5 }
    }
    sphere {
       < 0, 0, 0 >
       35
      texture { tx_cristal }
      interior { ior 1.5 }
    }
  }

#declare logotipo =
  text {
    ttf "arial.ttf"
    "LIV"
    0.15, 0
  }

#macro par_buracos(i)
  union {
    cylinder {
      <0,10,-60>
      <0,10,60>
      2
      translate <5*i-20,0,0>
      texture { tx_cristal2 }
      interior { ior 1.5 }
    }
    cylinder {
      <0,-10,-60>
      <0,-10,60>
      2
      translate <5*i-20,0,0>
      texture { tx_cristal2 }
      interior { ior 1.5 }
    }
  }
#end

difference {
	union {
		object { base }
		object { logotipo texture { tx_metal } scale <30,15,100> translate <-20,-5,0> }
	}
#declare i=0;
#while (i<9)
	par_buracos(i)
	#declare i=i+1;
#end
}