// Last edited on 2003-12-14 20:18:55 by stolfi
// MC930 - Laboratorio 9 - Logo para o LIV
// Martim Carbone - RA:002193

#declare ctr = < 0.00, 0, 0.00 >;
#declare camDir = < 1, 2, -6 >;

camera {
  location   ctr + 1.25*camDir
  right      1.00*x
  up         1.00*y
  sky        y
  look_at    ctr
}
 

light_source { <0, 9, -10> color rgb <1, 1, 1>}
light_source { <0, 8, 10> color rgb <1, 1, 1>}
light_source { <-2, -2, 10> color rgb <1, 1, 1>}

background{ color rgb < 0.5, 0.5, 0.5 > }

#declare tx_borda = 
  texture {
    pigment {color <0.2,0.4,0.8>}
    finish {
      ambient 0.1 diffuse 0.4
      reflection 0.1
      specular 0.5 roughness 0.001
    }
  }

// Borda do monitor

#declare borda = 
  box {
    <3,-3,0>
    <-3,3,1>
    texture{tx_borda}
    // interior {ior 1}
  }

// Tela do monitor

#declare tela = 
  box {
    <2.4,-2.4,0.0>
    <-2.4,2.4,-0.01>
    texture{pigment{color rgb <0.3, 0.3, 0.3>}}
  }

#declare botao = 
  difference {
    sphere {
      <0,0,0>,0.2
    }
    box {
      <0.5,-0.5,0>
      <-0.5,0.5,-0.5>
    }
  }

// Letra 'L'

#declare letra_l = 
  text {    
    ttf "arial.ttf"
    "L"
    0.3, 0
    texture {
      pigment {rgb <1,0,0>}
      finish {
  ambient 0.05 diffuse 0.2
  reflection <1,0,0>
  specular 0.90 roughness 0.05
  metallic
      }
    }
  }

// Letra 'I'

#declare letra_i = 
  text {    
    ttf "arial.ttf"
    "I"
    0.3, 0
    texture {
      pigment {rgb <0,1,0>}
      finish {
  ambient 0.05 diffuse 0.2
  reflection <0,1,0>
  specular 0.90 roughness 0.05
  metallic
      }
    }
  }

// Letra 'V'

#declare letra_v = 
  text {    
    ttf "arial.ttf"
    "V"
    0.3, 0
    texture {
      pigment {rgb <0,0,1>}
      finish {
  ambient 0.05 diffuse 0.2
  reflection <0,0,1>
  specular 0.90 roughness 0.05
  metallic
      }
    }
  }

#declare elipse = 
  difference {
    sphere {
      <0,0,0>, 1.1
      scale 1.6*x
    }
    box {
      <2,-2,0>
      <-2,2,-2>
    }
  }

// Pixel da tela

#declare pixel = 
  difference {
    sphere {
      <0,0,0>, 1
    }
    box {
      <1,-1,0>
      <-1,1,-1>
    }
  }

// LEDs

#declare led = 
  sphere {
    <0,0,0> 0.1
    texture{pigment{color rgb <0,1,0>}}
  }

// Pingo no 'I'

#declare pingo = 
  union {
    object {
      pixel
      texture{pigment{color rgb <1,0,0>}}
      translate <0.7,-0.4,0>
    }
    object {
      pixel
      texture{pigment{color rgb <0,1,0>}}
      translate <-0.7,-0.4,0>
    }
    object {
      pixel
      texture{pigment{color rgb <0,0,1>}}
      translate <0,0.8,0>
    }
  }

union {
  object{borda}
  object{tela}
  object{
    elipse
    texture{pigment{color <0.7,0.7,0>}}
    translate <0.1,0.5,-0.1>
  }
  object{
    letra_l
    scale 1.5
    translate <-1,0,-0.15>
  }
  object{
    letra_i
    scale 1.5
    translate <0,0,-0.15>
  }
  object{
    letra_v
    scale 1.5
    translate <0.5,0,-0.15>
  }
  object{
    pingo
    scale 0.1
    translate <0.1,1.4,-0.2>
  }
  object{
    led
    translate <2,-2.7,0>
  }
  object{
    led
    translate <2.3,-2.7,0>
  }
  object {
    botao
    texture{pigment{color rgb <0.6, 0.6, 0.6>}}
    translate <-2.6,-2.7,-0.05>
  }
  object{
    led
    scale 0.5
    translate <-2.6,-2.7,-0.02>
  }
  object{
    led
    translate <2.6,-2.7,0>
  }
}