// MC930 A, S2 2003
// Autor: Leonel Aguilar Gayard
// RA 009103
// Data 11/11/2003
// Tema: Logotipo para o Laboratório de Informação Visual

#include "colors.inc"
#include "metals.inc"
#include "textures.inc"
#include "finish.inc"


// ======================================================================
// CÂMERA 

camera {
  location  <0 , -20, 5>  // Posição do observador.
  
  right     -1.0*x         // Largura RELATIVA da imagem.
  up        0.75*y         // Altura RELATIVA da imagem.      
  sky       z              // Qual direção é "para cima"?
  look_at   < 0, 0, 4 >    // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  0.5 * < +30.0, +10.0, +90.0 >                // Posição da lâmpada.
  color rgb 1.3 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  0.5 * < +10.0, -10.0, +10.0 >                // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}


  #declare cor_cristal_azul = <0.3, 0.4, 1>;
  #declare tx_cristal_azul = 
    texture {
      finish {
        ambient 0.1 diffuse 0.1
        reflection 0.25
        specular 1 roughness 0.001
      }
      pigment { color cor_cristal_azul filter 1 }
    }
  #declare cor_cristal_verde = <0.2,0.9,0.2>;
  #declare tx_cristal_verde = 
    texture {
      finish {
        ambient 0.1 diffuse 0.1
        reflection 0.70
        specular 1 roughness 0.010
      }
      pigment { color cor_cristal_verde filter 1 }
    }
  #declare cor_metal_ouro = <1,1,0>;
  #declare tx_metal_ouro = 
    texture {
      finish {
        ambient 0.05 diffuse 0.05
        reflection cor_metal_ouro
        specular 0.20 roughness 0.05
      }
      pigment { color cor_metal_ouro }
    }



#declare perna = union {
    cylinder { <0,0,0>, <0,0,5>, 1
        texture { tx_metal_ouro }
        interior { ior 1.3 }
    }
    box { <0,0,0>, <5, 2.5, 1> translate <-1.25, -1.25, -1>
        texture { Dark_Wood }
    }
}

#declare quadril = union {
    cylinder { <0,0,0>, <5,0,0>, 1 texture { tx_cristal_verde } }      // o quadril
    object { perna rotate 270 * z translate <1.5, 0, -5> scale 0.7 }
    object { perna rotate 270 * z translate <5.5, 0, -5> scale 0.7 }
}

#declare corpo = union {
    cylinder { <0,0,0>, <0,0,6>, 0.6 texture { tx_metal_ouro } } // o corpo e o pescoco
    cylinder { <0,0,0>, <5,0,0>, 1 translate <-2.5, 0, 4> texture { tx_cristal_verde } }            // os bracos
    object { quadril translate <-2.5, 0, 0 > }
}

#declare logotipo =
object {
    text {
        ttf "latinwd.ttf"
        "L I V"
        1.4, 0
    }
    translate <0,0,-0.2>
    texture { tx_metal_ouro }
}


#declare cabeca = object {
    union {
        object {
            difference {
                cylinder { <0,0,0>, <0,0,1>, 1 }
                cylinder { <0,0,-10>, <0,0,10>, 0.9 }
            }
            scale <5, 1, 1>
            texture { tx_cristal_azul }
        }
        union {
            object { cylinder { <0,0,0>, <0,0,1>, 0.7 } scale <5,1,1> texture { tx_cristal_azul } }
            object { logotipo translate <-2.2, -0.3, 0> }
        }
    }
}

background { color Grey }

union {
    object { corpo scale 0.8 }
    object { cabeca rotate 90 * x translate <0,0,5.6> }
}

plane { z, -3 texture { DMFWood6 } }