// Vitor Sexto Bernardes  -  RA 010063

#declare dist_x = 4;

// ======================================================================
// CÂMERA 

camera {
  location  <dist_x, 15, 1>             // Posição do observador
  right     1.0*x                  // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.
  sky       z                      // Qual direção é "para cima"?
  look_at   <dist_x, 0, 1.8>              // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  < dist_x, 30, 10 >              // Posição da lâmpada.
  color rgb 3 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

// ======================================================================
// DESCRIÇÃO DA CENA

background { color rgb < 0.75, 0.80, 0.85 > }

#declare cor_olho = < 0.8, 0.8, 1 >;
#declare tx_olho =
  texture {
    finish {
      ambient 0.1 diffuse 0.1
      reflection 0.25
      specular 1 roughness 0.001
    }
    pigment { color cor_olho filter 1 }
  }


#declare cor_placa = < 0.7, 0.7, 1 >;
#declare tx_placa =
  texture {
    pigment { rgb cor_placa }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_placa
      specular 0.1 roughness 0.05
    }
  }

#declare tx_letra =
  texture {
    pigment { rgb <.56, .93, .56> }
    finish {
      ambient .05 diffuse .1
      phong .3
    }
  }



#declare chao =
  plane {
    <0, 0, -1>, 1
    pigment {
      wood turbulence 1 scale 4*<1,1,1>
    }
    finish { ambient 0.1 specular .25 reflection .2 }
  }


#declare L_V =
  text {
    ttf             // font type (only TrueType format for now)
    "arial.ttf",    // Microsoft Windows-format TrueType font file name
    "L     V",      // the string to create
    .2,             // the extrusion depth
    0               // inter-character spacing
    texture { tx_letra }
    scale <3,3,1>
    rotate 90*x
    translate <1, 0, 1>
  }

#declare I =
  intersection {
    sphere {
      <-1, 0, 2>, 2
    }
    sphere {
      <1, 0, 2>, 2
    }
    texture { tx_letra }
    scale <.3, .2, .8>
    translate <4, 0, .4>
  }

#declare olho =
  intersection {
    sphere {
      <0, -1, 2>, 2
    }
    sphere {
      <0, 1, 2>, 2
    }
    texture { tx_olho }
    scale <1.05, .2, 1.05>
    translate <4, -2, 0>
  }

#declare olho_I =
  union {
    object { olho }
    object { I }
    translate <.5, 0, 0>
  }

#declare placa =
  intersection {
    cylinder {
      <0, -1, 3>, <0, .6, 3>, 5
    }
    cylinder {
      <0, 0, -1>, <0, .5, -1>, 4
    }
    texture { tx_placa }
    scale <1.7, 1.5, 1.5>
    translate <4.7, -4, 1.7>
  }


// ======================================================================
// CENA FINAL

object { chao }
union {
  object { L_V }
  object { olho_I }
  object { placa }
  translate <0,0,1>
}