// Last edited on 2003-12-13 21:11:32 by stolfi
// MC930 A, S2 2003
// Autor: Leonel Aguilar Gayard
// RA 009103
// Data 28/11/2003
// Tema: Espetáculo do crescimento

#include "colors.inc"
#include "metals.inc"

#declare ctr = < 0, 0, 0.7 >;
#declare camDir = < 0, -5, 0>;

camera {
  location   ctr + 0.75*camDir
  right      -0.75*x
  up         0.75*y
  sky        z
  look_at    ctr
}

light_source {
  0.5 * < +30.0, +10.0, +90.0 >                // Posição da lâmpada.
  color rgb 1.3 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

light_source {
  0.5 * < +10.0, -10.0, +10.0 >                // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

light_source {
  0.5 * < 0, -10, 10>                // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

#declare clock1 = clock;

#declare mundo = blob {
    threshold 0.5

    // mundo
    #declare raio_maior = 4;
    #declare forca_maior = 0.8;
    sphere { <0,0,0>, raio_maior, forca_maior }

    // Brasil, composto de 3 esferas
    // raio da esfera menor
    #declare raio_menor = 2.5;
    // distancia entre as esferas menores
    #declare distancia = 0.3 * clock1 * clock1;
    // forca das esferas menores
    #declare forca = 0.15;
    // distancia que o Brasil toma do mundo
    // #declare dist2 = 1 + abs(2 * sin(3 * 2 * pi * clock1));
    #declare dist2 = 3 * sqrt(clock);

    // esferas vao se distanciando
    sphere { <dist2, 0, distancia>, raio_menor, forca  }
    sphere { <dist2, 0, -distancia>, raio_menor, forca  }
    sphere { <dist2, distancia, 0>, raio_menor, forca  }
    sphere { <dist2, distancia, 0>, raio_menor, forca  }
}

#declare alfa = 0.7 * clock - 0.5;
#declare beta = 0.5;

#declare aura =
sphere { <0,0,0>, raio_menor
    hollow
    texture { pigment { color rgb <1,0.2,0.2> transmit 1 } }
    interior {
        media {
            emission  alfa * <10, 0.8, 0.2>
            scattering { 1, beta * <0.8, 0.2, 0.2> }
        }
    }
}

background { Black }

object {
    union {
        object {
             mundo pigment {
                 image_map { png "../txmaps/earth-land.png" map_type 1 }
                 rotate 45 * z
                 rotate 60 * <1,1,1>
                 rotate 35 * z
             }
         }
         #if (clock > 0.5)
             object { aura translate <dist2, 0, 0> }
         #end
    }
    rotate -90 * y
    scale .25
}