// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2004-09-14 15:25:26 by volneids


// ======================================================================
// CÂMERA 

// Modificada, para te ver melhor...
camera {
  location  <  4.00, 2.00, 8.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        1.50*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.


// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >           // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >           // Posição da lâmpada.
  color rgb 1.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 


// ======================================================================
// DESCRIÇÃO DA CENA 

// Roses are red, and the sky is blue...
background{ color rgb < 0.05, 0.80, 0.85 > }

#declare raio = 2.000;

// A tinta "A" é bastante brilhante, e avermelhada
#declare tinta_A = 
  texture {
    pigment { color rgb < 1.00, 0.10, 0.10 > }
    finish {
      ambient .2
      diffuse .6
      specular .75
      roughness .001
      reflection {
         .5
      }
    }
  }

// A tinta B é um pouco mais exótica
#declare tinta_B = 
  texture {
    normal { bumps 0.4 scale 0.2 }	// Bonitas manchas, B!
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

// Bolota que ficará centrada na cena
#declare bola =
  sphere {
    < 0.00, 0.00, 0.00 >, 2.00 
    texture { tinta_A }
  }

// Declara o pino da furadeira! 
#declare furo = 
  cylinder {
    < 0.00, 0.00, +2.00 >,		// Eixos humanamente manipuláveis...
    < 0.00, 0.00, -2.00 >,
    1.50
  }
  
#declare pino1 = 
  cylinder {
    < +2.50, 0.00, 0.00 >,		// Eixos humanamente manipuláveis...
    < -2.50, 0.00, 0.00 >,
    0.75
    texture { tinta_B }
  }
  
#declare pino2 = 
  cylinder {
    < 0.00, +2.50, 0.00 >,		// Eixos humanamente manipuláveis...
    < 0.00, -2.50, 0.00 >,
    0.75
    texture { tinta_B }
  }


// ======================================================================
// Aqui está a cena, finalmente:

// Constroi a bola furada transpassada por dois pinos cruzados
union {
  // Colocada uma bola furada na cena
  difference { 
    object { bola } 
    object { furo }
  }
  // Dois pinos cruzam a mesma
  object { pino1 }
  object { pino2 }
}

// Colocando um chão na cena
plane { z, -10		// Normal ao eixo x, distância de -10
  pigment {		// Padrão de "xadrez"
    checker color rgb<1.0, 1.0, 0.0> color rgb<0.0, 1.0, 1.0>
    scale 2
  }
  finish {		// Um acabamento magnifique...
        ambient .1
        diffuse .1
        reflection .2
        specular 1
        roughness .001
        irid {
          0.35
          thickness .5
          turbulence .5
        }
  }
}