// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  3.00, 5.00, 4.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare caixa_centro = 
  box {
    <-1.00, -0.60, +1.30>
    <+1.00, +0.60, -0.40>
    texture {tinta_B}
  }

#declare caixa_dentro_centro = 
  box {
    <-0.90, -0.50, +1.40>
    <+0.90, +0.50, -0.35>
    texture {tinta_B}
}

#declare dobradica_ponta = 
  cylinder {
    <-0.45, 0, 0>
    <+0.45, 0, 0>
    0.05
    rotate 90*z
  }

#declare ponta = 
  cone {
    <-0.6, 0.0, 0>, 0.40
    <+0.6, 0.0, 0>, 0.01
    texture{tinta_A}
  }

#declare base =
  box {
    <-0.60, 0.30, -0.4>
    <+0.60, -0.30, -0.9>
    texture {tinta_B}
  }

#declare sbase = 
  box {
    <-1.00, +0.6, -0.90>
    <+1.00, -0.6, -1.20>
    texture {tinta_B}
  }

#declare tampa =
  box {
   <-1.00, +0.6, -0.20>
   <+1.00, -0.6, +0.10>
  rotate 70*x
  texture {tinta_B}
  }

union{
  difference {  
    object { caixa_centro }
    object { caixa_dentro_centro }
  }
  union {
    object { dobradica_ponta  translate <+0.95,0,+1.35>}
    object { ponta translate <+1.65,0,+0.95>}
  }
  union {  
    object { dobradica_ponta  translate <-0.95,0,+1.35>}
    object { ponta 
             rotate -100*y 
             translate <-1.40, 0, +1.87>}
  
    object { tampa translate <0,-0.5,2>}
  }
  union {
    object {base}
    object {sbase}
  }
}