// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  40.00, 40.00, 40.00 >  // Posição do observador.
  right     1.00*x                // Largura RELATIVA da imagem.
  up        -0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 0.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 3.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 0.50, 0.50, 0.50 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare corpo =
  box {
    < 0.00, 0.00, 0.00 >,
    < 10.00, 15.00, 5.00 >
    texture { tinta_B }
  }

#declare ponta_esferica =
  sphere {
    < 5.00, 15.00, 5.00 >,
    5.00
    texture { tinta_A }
  }

#declare offset_ponta_esferica =
  box {
    < -1.00, 9.00, 5.00 >
    <  11.00, 21.00, 11.00>
    texture { tinta_A }
  }

#declare offset2_ponta_esferica =
  box {
    < -1.00, 9.00, 0.00 >
    < 11.00, 15.00, 11.00>
    texture { tinta_A }
  }

#declare pes =
  box {
    < 0.00, 0.00, 0.00 >,
    < 10.00, 10.00, 1.00 >
    texture { tinta_A }
    translate < 2.50, 2.50, -6.00> 
  }

#declare suporte =
  box {
    < 0.00, 0.00, 0.00 >,
    < 5.00, 5.00, 6.00>
    texture { tinta_A }
    translate < 5.00, 5.00, -6.00>
  }

#declare ponta_triangular =
  box {
    < 0.00, 0.00, 0.00 >
    < 10.00, 30.00, 5.00 >
    texture { tinta_A }
  }

#declare offset_ponta_triangular =
  box {
    < -1.00, -1.00, -1.00 >
    < 11.00, 31.00, 21.00>
    texture { tinta_A }
    translate -20.00*z
    rotate 30*x
  }	

union { 
  object { corpo }
  difference {
    object { ponta_triangular }
    object { offset_ponta_triangular }
    rotate 180*z
    translate 10*x
    translate -5*z
    rotate -60*x
    translate 5*z
  }
  difference {
    object { ponta_esferica }
    object { offset_ponta_esferica }
    object { offset2_ponta_esferica }
    translate < -5.00, -15.00, -5.00>
    rotate 30*x
    translate < 5.00, 15.00, 5.00>
  }
  union {
    object { suporte }
    object { pes }
    translate -10*x
    rotate -30*y
    translate 10*x
  }
}