// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  < 50, 0, 0 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 1, 1, 1 > }

#declare cor_aco = 
  texture {
    pigment { color rgb < 0.50, 0.50, 0.50 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare cor_junta = 
  texture {
    pigment { color rgb < 0, 0, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare principal = 
  box {
    <4,-7,2.5>, 
    <-4,7,-2.5>
    texture { cor_aco }
  }

#declare fundo = 
  box {
    <4,-7,2.5>,
    <-4,-12,8.5>
    texture { cor_aco }
  }

#declare frente = 
  difference {
    cone {
      <0,7,2.5>,4,
      <0,7,10.5>,0
      texture { cor_aco }
    }
    box {
      <4,7,2>,
      <-4,3,11>
    }
  }

#declare base = 
  union {
    //base principal
    box {
      <2,-3,-2.5>,
      <-2,3,-6.5>
      texture { cor_aco }
    }
    //pezinho esquerdo
    box {
      <2,-3,-6.5>,
      <-2,-5,-9.5>
      texture { cor_aco }
    }
    //pezinho direito
    box {
      <2,3,-6.5>,
      <-2,5,-9.5>
      texture { cor_aco }
    }
  }

#declare juntas = 
  union {
    //junta fundo
    cylinder {
      <4.25,-7,2.5>,
      <-4.25,-7,2.5>,
      0.50
      texture { cor_junta }
    }
    //junta frente
    cylinder {
      <4.25,7,2.5>,
      <-4.25,7,2.5>,
      0.50
      texture { cor_junta }
    }
    //junta pezinho esquerdo
    cylinder {
      <2.25,-3,-6.5>,
      <-2.25,-3,-6.5>,
      0.5
      texture { cor_junta }
    }
    //junta pezinho direito
    cylinder {
      <2.25,3,-6.5>,
      <-2.25,3,-6.5>,
      0.5
      texture { cor_junta }
    }
  }

// Aqui está a cena, finalmente:

union {
  object { principal }
  object { fundo }
  object { frente }
  object { base }
  object { juntas }
}