// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  25.00, 6.00, 4.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e cor da luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e cor da luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare cor_coroa = < 1.0, 1.0, 0.0>;

#declare tinta_A = 
  texture {
    pigment { rgb cor_coroa }
    finish { reflection cor_coroa*.7 diffuse 0.05 
             specular 0.20 roughness 0.05 ambient 0.05 }
   
  }

#declare tinta_B = 
  texture {
    pigment { color rgb <0, 0.6, 0> filter 1}
    finish { diffuse 0.1 specular 1 reflection 0.25 
             roughness 0.001 ambient 0.1 }
  }
  
#declare tinta_C = 
  texture {
    pigment { color rgb <1.0, 0.0, 0> filter 1}
    finish { diffuse 0.1 specular 1 reflection 0.25 
             roughness 0.001 ambient 0.1 }
  }

plane { z, -5
  texture {
    pigment { checker <1,1,1>, <0,0,.8> }
    finish { ambient 0.1 diffuse 0.9 }
    scale 2.0
  }
}
 
  #declare caixa =
  box {
    < 8.00, -1.00, -2.00 >, 
    < -8.00, 1.00, 2.  > 
    texture { tinta_A }
  }

  #declare toroide1 = 
  torus {
    5,
    3
    rotate -90*x
    texture {tinta_A}
  }

  #declare cilindro = 
  cylinder {
    <0.0, 0.0, -4.0>,
    <0.0, 0.0, 4.0>,
    6
    texture {tinta_A} 
  }

  lathe {
    linear_spline
    9,
    <.5,0>, <1,.5>, <1,1.5>, <.5,2>, <.5,2.5>, <1,2.5>, <1,2.7>, <.5,2.7>, <.5,3> 
    texture { tinta_A }
    finish {
      ambient .3
      phong .75
    }
   rotate 90*x
   translate <6.0, 0.0, 2.7>
  }

  lathe {
    linear_spline
    3,
    <.5,0>, <1,.5>, <.5,1>
    texture { tinta_B }
    interior {ior 1.5}
    finish {
      ambient .3
      phong .75
    }
   rotate 90*x
   translate <0.0, 6.0, 2.7>
  }

  lathe {
    linear_spline
    3,
    <.5,0>, <1,.5>, <.5,1>
    texture { tinta_B }
    interior {ior 1.5}
    finish {
      ambient .3
      phong .75
    }
   rotate 90*x
   translate <0.0, -6.0, 2.7>
  }

#declare toroide2 = 
torus {
  1, .5
 texture {tinta_C}
  interior {ior 1.5}
  rotate -90*x


}

// Aqui está a cena, finalmente:
union {
  object { toroide2 
    translate <0, 6, 4>}
  object { toroide2 
   translate <0, -6, 4>}
  difference{
    object { toroide1 }
    object { cilindro }
    object { caixa 
    rotate -15*z}
    object { caixa 
    rotate +15*z}
    object { caixa 
    rotate -45*z}
    object { caixa 
    rotate +45*z}
  }
}