// Last edited on 2005-01-05 21:54:29 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A =
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.8 specular 0.4 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B =
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.8 specular 0.4 roughness 0.005 ambient 0.1 }
  }

#declare cor_esmeralda = <0.2 0.5 0.4>;
#declare tx_esmeralda =
   texture {
     finish {
      ambient 0.1 diffuse 0.2 reflection 0.04
      specular 1 roughness 0.003
     }
     pigment { color cor_esmeralda filter 1 }
   }

#declare cor_ruby = <0.6 0.4 0.3>;
#declare tx_ruby =
   texture {
     finish {
      ambient 0.1 diffuse 0.2 reflection 0.04
      specular 1 roughness 0.003
     }
     pigment { color cor_ruby filter 1 }
   }

#declare cor_prata = <0.7 0.7 0.8>;
#declare tx_prata =
   texture {
     pigment { rgb cor_prata }
     finish {
       ambient 0.05 diffuse 0.1
       reflection cor_prata
       specular 0.3 roughness 0.7
     }
   }

#declare cor_ouro =  < 1.00, 0.80, 0.10 >;
#declare tx_ouro =
   texture {
     pigment { rgb cor_ouro }
     finish {
       ambient 0.05 diffuse 0.05
       reflection cor_ouro
       specular 0.20 roughness 0.05
     }
   }

#declare base =
    torus {
       3,0.5
       texture { tx_ouro }
     }

#declare mastro1 =
    lathe {
      linear_spline
      6,
      <0,2>, <0.2,1.3>, <0.6,1.0>, <0.3,0.8>, <0.5, 0.5>, <0.25,0>
      texture { tx_ouro }
    }

#declare mastro2 =
    lathe {
      linear_spline
      3,
      <0,0.9>, <0.45,0.6>, <0.2,0>
      texture { tx_prata }
    }

#declare mastro3 =
    cylinder {
      <0,0,0>
      <0,0,0.6>
      0.45
      texture { tx_esmeralda }
      interior { ior 1.5 }
    }

#declare pedra1 =
    box {
      <0.25, -0.25, -0.25>
      <-0.25, 0.25, 0.25>
      texture { tx_ruby }
      interior { ior 1.5 }
 }

#declare pedra2 =
    box {
      <0.15, -0.15, -0.15>
      <-0.15, 0.15, 0.15>
      texture { tx_esmeralda }
      interior { ior 1.5 }
 }

#declare chao =
    plane { z, -4
         texture {
              pigment { checker <0.5,0.5,0.5>, <1,1,1>}
              finish { ambient 0.6 diffuse 0.4 }
              scale 1.5
       }
   }

union {
    object {chao}
    object {base rotate 90*x}
    object {mastro1 rotate 90*x translate <3, 0, 0.4>}
    object {mastro2 rotate 90*x translate <2.7, -1.3, 0.3>}
    object {mastro2 rotate 90*x translate <2.7, 1.3, 0.3>}
    object {mastro3 translate <1.6, 2.4, 0.3>}
    object {mastro3 translate <1.6, -2.4, 0.3>}
    object {pedra1 rotate 45*x translate <3.3, 0, 0> }
    object {pedra2 rotate 45*x translate <3.1, 1.5, 0> }
    object {pedra2 rotate 45*x translate <3.1, -1.5, 0> }

}

#include "camlight.inc"
camlight(<0,0,0>,<8.00,1.00,2.50>,1.15,z,1.0)