// Last edited on 2005-01-05 23:09:59 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare cor_coroa = < 0.90, 0.90, 0.60 >;

#declare tx_espelho =
  texture {
    pigment { color rgb cor_coroa }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_coroa
      specular 0.80 roughness 0.05
    }
  }

#declare cor_pedra = < 0.20, 0.20, 0.60 >;
#declare tx_cristal =
  texture {
    finish {
      ambient 0.1 diffuse 0.1
      reflection 0.25
      specular 1 roughness 0.001
    }
    pigment { color rgb cor_pedra filter 1 }
  }

#declare coroa =
  lathe {
    17,
    <18,0>,<18,6>,<17,6>,<17,10>,<18,10>,<18,20>,<25,27>,<25,36>,
    <24,36>,<24,27>,<17,20>,<17,11>,<16,11>,<16,5>,<17,5>,<17,0>,<18,0>
  }

#declare base =
  torus {
    17.5, 3
  }

#declare corte =
  prism {
    30, -30, 4,
    <-10,-6>, <10,-6>, <18,6>, <-18,6>
    rotate -90*x
    translate <0, 34, 0>
  }

#declare metal =
  difference {
    union {
      object { coroa }
      object { base }
    }
    object {
      corte
      rotate 45*y
    }
    object {
      corte
      rotate -45*y
    }
    texture { tx_espelho }
  }

#declare pedra =
  sphere {
    <0,0,0>, 2
    texture { tx_cristal }
    interior { ior 1.5 }
  }

#declare pedrinha =
  sphere {
    <0,0,0>, 1
    texture { tx_cristal }
    interior { ior 1.5 }
  }

plane {y, 0
  texture {
    pigment{checker <0.5,0.5,0.5>,<0.8,0.8,0.8>}
    finish {ambient 0.6 diffuse 0.4}
    scale 30.0
  }
}

union {
object {metal}
object {
  pedra
  translate < 0.00, 32.00, 25.00>
}

object {
  pedrinha
  translate < 0.00, 8.00, 17.00>
}
object {
  pedrinha
  translate < 0.00, 8.00, -17.00>
}
object {
  pedrinha
  translate < 14.72, 8.00, 8.50>
}
object {
  pedrinha
  translate < 14.72, 8.00, -8.50>
}
object {
  pedrinha
  translate < -14.72, 8.00, 8.50>
}
object {
  pedrinha
  translate < -14.72, 8.00, -8.50>
}
}

#include "camlight.inc"
camlight(<0,20,0>,<30,40,100>,0.90,y,1.0)