// Last edited on 2005-01-05 22:06:12 by stolfi
// Processed by remove-cam-lights

background{
  color rgb <0.75, 0.80, 1.0>
}

#declare dourado = < 1.00, 1.00, 0.60>;

#declare vermelho = < 1.00, 0.00, 0.00>;

#declare ouro =
  texture {
    pigment { rgb dourado }
    finish { ambient 0.05
             diffuse 0.05
             reflection dourado
             specular 0.2
             roughness 0.05
           }
  }

#declare rubi =
  texture {
    pigment { rgb vermelho filter 1}
    finish { diffuse 0.1
             specular 1
             roughness 0.001
             ambient 0.1
             reflection 0.25
           }
  }

#declare vidro =
  texture {
    pigment { rgb <0.7,0.7,0.7> filter 1}
    finish { diffuse 0.1
             specular 1
             roughness 0.001
             ambient 0.01
             reflection 0.25
           }
  }

#declare pano =
  texture {
    pigment { rgb <1, 0.6, 0.6> }
    finish { diffuse 0.05 }
  }

#declare negro =
  texture {
    pigment { color rgb < 0.00, 0.00, 0.00 > }
    finish { diffuse 0.1
             specular 1
             roughness 0.001
             ambient 0.1
             reflection 0.25
           }
  }

#declare coroa =
  lathe {
    bezier_spline
    8,
    <4.5, -1>, <6,0>, <5,1>, <4,2>, <4,2>, <3,3>, <8,5>, <4,10>
    texture { ouro }
  }

#declare joia =
  sphere {
    < 0.00, 0.00, 0.00 >, 0.5
    texture { rubi }
    interior { ior 1.5 }
  }

#declare raias =
  box {
    < 5.00, 5.00, 5.00>,
    <-5.00,-5.00, -5.00>
    texture { ouro }
    rotate x*45
  }

#declare enfeite =
  torus {
    4, 0.5
    texture { vidro }
    translate y*9.5
    interior { ior 1.5 }
  }

#declare colcha =
  torus {
    3.5, 1.50
    texture { pano }
    translate y*-0.5
  }

#declare fita =
  torus {
    3.75, 0.50
    texture { negro }
    translate y*2
  }

union {
  difference {
    object { coroa }
    object { raias translate 13*y}
    object { raias rotate y*90 translate 13*y}
  }
  object { enfeite }
  object { colcha }
  object { fita }
  object { joia translate 4.0*x translate 4.0*z translate 7*y }
  object { joia translate -4.0*x translate 4.0*z translate 7*y }
  object { joia translate 4.0*x translate -4.0*z translate 7*y }
  object { joia translate -4.0*x translate -4.0*z translate 7*y }
}

plane { y, -5
  pigment { checker color rgb <1.0, 1.0, 1.0> color rgb <0.5,0.5,0.5> scale 2 }
  finish { ambient 0.6 diffuse 0.4 }
}

#include "camlight.inc"
camlight(<0,5,0>,<20.00,5.00,20.00>,0.75,y,1.0)