// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  25.00, 25.00, 25.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

// background{ color rgb < 0.75, 0.80, 0.85 > }

background{ color rgb <1.0, 1.0, 1.0> }

#declare cor_adorno = <1.00, 0.00, 0.00>;
#declare tx_adorno =
  texture {
    finish {
      ambient 0.1 diffuse 0.1 reflection 0.15
      specular 1 roughness 0.001
    }
    pigment { color cor_adorno filter 1}
  }

#declare cor_corpo = <0.80, 0.80, 0.0>;
#declare tx_corpo = 
  texture {
    pigment { rgb cor_corpo }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_corpo
      specular 0.20 roughness 0.05
    }
  }

#declare cor_cinta = <0.40, 0.40, 0.40>;
#declare tx_cinta = 
  texture {
    pigment { rgb cor_cinta }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_cinta
      specular 0.20 roughness 0.05
    }
  }

#declare cinta_baixa =
  torus {
    10, 1
    rotate 90*x
    texture { tx_cinta }
  }

#declare cinta_alta =
  torus {
    12, 1
    rotate 90*x
    translate 5*z
    texture { tx_cinta }
  }

#declare corpo_coroa =
  lathe {
    linear_spline
    4,
    <9.50,0>, <10.50,0>, <11.50,5>, <12.50,5>
    texture { tx_corpo }
    rotate 90*x
  }

#declare adorno =
  lathe {
    linear_spline
    9,
    <0,0>, <2,0>, <2,3>, <3,3>, <3,5>, <2,5>, <2,7>, <3,8>, <0,15>
    texture { tx_adorno }
    rotate 90*x
    scale 0.5
    interior { ior 1.2 }
  }

// piso
  plane {
    z,
    -1
    texture {
      pigment { checker <0.5,0.5,0.5>, <0,0,0> }
      finish { ambient 01 diffuse 0.9 }
      scale 15
    }
  }


 union {
  object { cinta_baixa }
  object { cinta_alta }
  object { corpo_coroa }

  object {
    adorno
    translate <0, -12, 6>
  }
  object {
    adorno
    translate <0, 12, 6>
  }
  object {
    adorno
    translate <-12, 0, 6>
  }
  object {
    adorno
    translate <12, 0, 6>
  }
 }