// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  < 30.00, 0.00, 10.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare cor_ouro = < 1.0, 0.8, 0.1 >;

#declare dourado = 
  texture {
    pigment { rgb cor_ouro }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_ouro
      specular 0.20 roughness 0.05
    }
  }

#declare cor_vinho = <1,0,0>;

#declare rubi = 
  texture {
    finish {
      ambient 0.1 diffuse 0.1 reflection 0.25
      specular 1 roughness 0.001
    }
    pigment { color cor_vinho filter 1 }
  }

#declare azul_marinho = 
  texture {
    pigment { color rgb < 0, 0, 0.7 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare paredao =
  plane { z, 0
    texture {
      pigment { checker <0,0,0>, <1,1,1> }
      finish { ambient 01 diffuse 0.9 }
    }
  }

#declare apoio_cabeca = 
  torus {
    4.5
    0.5
    texture { azul_marinho }
  }

#declare principal = 
  torus {
    4
    2
    texture { dourado }
  }

#declare topo = 
  lathe {
    5,
    <4,0>,
    <6,1>,
    <5,1>,
    <7,2>,
    <6,3>
    texture { dourado }
  }

#declare pedra =
  sphere {
    <5.5,0,2.5>
    1
    texture { rubi }
    interior { ior 1.5 }
  }
  
// Aqui está a cena, finalmente:

object { paredao }

difference {
  union {
    object { apoio_cabeca 
	     rotate 90*x
           }
    object { principal 
             rotate 90*x
             translate <0,0,2.25>
           }
    object { topo 
             rotate 90*x
             translate <0,0,3.5>
           }
    object { pedra } 
  }
  cylinder {
    <0,0,-0.6>,
    <0,0,6.5>,
    3.8
  }
}