// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  6, 8.50 , 7.50 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.0, 0.00, 2.50 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +0.0, +10.0, +20.0 >              // Posição da lâmpada.
  color rgb 1.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +10.0, 0.0, +20.0 >             // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tinta_marrom = 
  texture {
    pigment { color rgb < 0.8, 0.6, 0.4 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_azulclara = 
  texture {
    pigment { color rgb < 0.70, 0.70, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare tinta_vermelha = 
  texture {
    pigment { color rgb < 1.00, 0.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_cinza = 
  texture {
    pigment { color rgb < 0.50, 0.50, 0.50 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_granito =
 texture{
    pigment { granite }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare predio =
  box {
    < -2.0, -2.0, 0.00 >,
    <  2.0, 2.0, 6.00 >
    texture { tinta_marrom }
  }
  
#declare portal =
  difference{
  cylinder{
	<0.00, 2.01, 0.20>,
	<0.00, 2.00, 0.20>,
	0.80
	texture {tinta_vermelha}
  }
  box{
	<-1.00, 2.03, -1.00>,
	<1.00, 1.98, 0.00>
  }
}

#declare janelas =
 union{
	#declare gerador = seed(156987);
	#declare j = 0;
	#while (j < 5)
	  #declare i = 0;
          #while (i < 4)
	    #if (rand(gerador) > 0.5)	
	    	box{
	     		<-1.85+i, 2.01, 1.75+j>,
	    		<-1.15+i, 1.98, 1.25+j>
	    		texture {tinta_azulclara}
	    	}
	    #else	
	    	cylinder{
			<-1.50+i, 2.01, 1.5+j>,
			<-1.50+i, 1.98, 1.5+j>
			0.35 
			texture {tinta_azulclara}
	    	}
	    #end
	    #if (rand(gerador) > 0.5)
	   	 box{
	    		 <2.01, -1.85+i, 1.75+j>,
	    		 <1.98, -1.15+i, 1.25+j>
	    		 texture {tinta_azulclara}
	    	}
	    #else
		cylinder{
			<2.01, -1.5+i, 1.5+j>,
			<1.98, -1.5+i, 1.5+j>
			0.35 
			texture {tinta_azulclara}
	    	}
	    #end
	    #if (rand(gerador) > 0.5)	
	    	box{
	     		<-1.85+i, -2.01, 1.75+j>,
	     		<-1.15+i, -1.98, 1.25+j>
	     		texture {tinta_azulclara}
	    	}
	    #else
		cylinder{
			<-1.5+i, -2.01, 1.5+j>,
			<-1.5+i, -1.98, 1.5+j>
			0.35 
			texture {tinta_azulclara}
	    	}
	    #end
	    #if (rand(gerador) > 0.5)
	   	 box{
	     		<-2.01, -1.85+i, 1.75+j>,
	     		<-1.98, -1.15+i, 1.25+j>
	     		texture {tinta_azulclara}
	    	}
	    #else
		cylinder{
			<-2.01, -1.5+i, 1.5+j>,
			<-1.98, -1.5+i, 1.5+j>
			0.35 
			texture {tinta_azulclara}
	    	}
	    #end
	    #declare i = i + 1;
	  #end
	  #declare j = j + 1;
	#end

 }

#declare pararaio =
  union{
	cylinder{
		<1.50, 1.50, 5.90>,
		<1.50, 1.50, 6.50>
		0.05 
		texture {tinta_cinza}
	}
	sphere{
		<1.50, 1.50, 6.60>, 0.1
		texture {tinta_cinza}
	}	

  }

#declare chao =
plane { z, 0
	texture{
	        pigment {brick pigment{boxed},pigment{granite}}
		finish {ambient 0.1 diffuse 0.9}
		scale 0.1
	}
}

// Aqui está a cena, finalmente:


  union {
    object { predio }
    object { portal }
    object {janelas }
    object {pararaio}
    object {chao}
  }