// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  28.00, 28, 23 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   < 0.0, 0, -4 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color < 1.0, 0.90, 0.70 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.0, 0.80, 0.60 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
  
#declare Andar_1 = 
 box {
   < 00, 00, 0 >,
   < 16, 16, 2.5 >
   texture { tinta_B }
   translate <0,0,2.5>
 }   
 
 #declare Andar_2 = 
 box {
   < 00, 00, 0 >,
   < 14, 14, 2.5 >
   texture { tinta_A }
   translate <0,0,5>
 }   

#declare Andar_3 = 
 box {
   < 00, 00, 0 >,
   < 12, 12, 2.5 >
   texture { tinta_B }
   translate <0,0,7.5>
 }   

#declare Corta_Terreo = 
 box {
   < 00, 00, -0.1 >,
   < 16, 16, 2.5 >
   texture { tinta_A }
   translate <6, 6, 0,>
 }   
  
#declare Terreo =
  difference {
    object {Andar_1 texture { tinta_A} translate <0,0,-2.5>}
    object {Corta_Terreo}
  }

#declare g = seed(1329756);
  
#declare moldura_janela =
  cylinder {
    < 0, 0, 0 >,
    < 0.1, 0, 0 >,
    0.6
    texture {
      pigment { color rgb < 0.2, 0.2, 0.2 > }
      finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
    }
    //texture { tinta_B}
  }
  
#declare vidro_janela_azul = texture  {
  pigment { color rgb < 0.4, 0.5, 1 > }
  finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
}

#declare vidro_janela_verde = texture {
  pigment { color rgb < 0.4, 1, 0.5 > }
  finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
}

  
#declare vidro_janela =
  cylinder {
    < 0, 0, 0 >,
    < 0.11, 0, 0 >,
    0.5
    texture {vidro_janela_azul}
  }
  
   
#declare janela =
  union {
    object {moldura_janela}
    object {vidro_janela}
  }

  
    
#declare janelas_andar1 = 
  union {
    #declare i = 0; //Um lado
    #while (i<8)
      object {janela translate<16.01, i*2 +1, 3.2 + rand(g)*1.2>}
      #declare i = i + 1;
    #end
    
    #declare i = 0; 
    #while (i<8)
      object {janela rotate 90*z translate<i*2 +1, 16.01, 3.2 + rand(g)*1.2>}
      #declare i = i + 1;
    #end
  }
  
#declare janelas_andar2 = 
  union {
    #declare i = 0; //Um lado
    #while (i<7)
      object {janela translate<14.01, i*2 +1, 5.75 +rand(g)*1.2>}
      #declare i = i + 1;
    #end
    
    #declare i = 0; 
    #while (i<7)
      object {janela rotate 90*z translate<i*2 +1, 14.01, 5.75 + rand(g)*1.2>}
      #declare i = i + 1;
    #end
  }
  
#declare janelas_andar3 = 
  union {
    #declare i = 0; //Um lado
    #while (i<6)
      object {janela translate<12.01, i*2 +1, 8.25 + rand(g)*1.2>}
      #declare i = i + 1;
    #end
    
    #declare i = 0; 
    #while (i<6)
      object {janela rotate 90*z translate<i*2 +1, 12.01, 8.25 + rand(g)*1.2>}
      #declare i = i + 1;
    #end
  }
  
#declare janelas_terreo = 
  union {
    #declare i = 0; //Um lado
    #while (i<3)
      object {janela translate<16.01, i*2 +1, 1+rand(g)*1.2>}
      #declare i = i + 1;
    #end
    
    #declare i = 0; 
    #while (i<3)
      object {janela rotate 90*z translate<i*2 +1, 16.01, 1+rand(g)*1.2>}
      #declare i = i + 1;
    #end
  }
  
    
#declare chao =
  plane {z,0
    texture {
      pigment { checker <0,0.4,0>, <0,0.45,0>}
      finish  {ambient 0.1 diffuse 0.9}
      scale 3
    }
  }
 
 
  object {Terreo}
  object {Andar_1}
  object {Andar_2}
  object {Andar_3}
  
  object {janelas_terreo}
  object {janelas_andar1}
  object {janelas_andar2}
  object {janelas_andar3}
  object {chao}